net-libs/nodejs/nodejs-10.16.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 PYTHON_REQ_USE="threads"
   8
   9 inherit bash-completion-r1 eutils flag-o-matic pax-utils python-any-r1 toolchain-funcs xdg-utils
  10
  11 DESCRIPTION="A JavaScript runtime built on Chrome's V8 JavaScript engine"
  12 HOMEPAGE="https://nodejs.org/"
  13 SRC_URI="https://nodejs.org/dist/v${PV}/node-v${PV}.tar.xz"
  14
  15 LICENSE="Apache-1.1 Apache-2.0 BSD BSD-2 MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x64-macos"
  18 IUSE="cpu_flags_x86_sse2 debug doc icu inspector +npm +snapshot +ssl systemtap test"
  19 REQUIRED_USE="
  20         inspector? ( icu ssl )
  21         npm? ( ssl )
  22 "
  23
  24 RDEPEND="
  25         >=dev-libs/libuv-1.28.0:=
  26         >=net-dns/c-ares-1.15.0
  27         >=net-libs/http-parser-2.9.0:=
  28         >=net-libs/nghttp2-1.39.2
  29         sys-libs/zlib
  30         icu? ( >=dev-libs/icu-64.2:= )
  31         ssl? ( >=dev-libs/openssl-1.1.1:0= )
  32 "
  33 DEPEND="
  34         ${RDEPEND}
  35         ${PYTHON_DEPS}
  36         systemtap? ( dev-util/systemtap )
  37         test? ( net-misc/curl )
  38 "
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-10.3.0-global-npm-config.patch
  41 )
  42 S="${WORKDIR}/node-v${PV}"
  43
  44 pkg_pretend() {
  45         (use x86 && ! use cpu_flags_x86_sse2) && \
  46                 die "Your CPU doesn't support the required SSE2 instruction."
  47
  48         ( [[ ${MERGE_TYPE} != "binary" ]] && ! test-flag-CXX -std=c++11 ) && \
  49                 die "Your compiler doesn't support C++11. Use GCC 4.8, Clang 3.3 or newer."
  50 }
  51
  52 src_prepare() {
  53         tc-export CC CXX PKG_CONFIG
  54         export V=1
  55         export BUILDTYPE=Release
  56
  57         # fix compilation on Darwin
  58         # https://code.google.com/p/gyp/issues/detail?id=260
  59         sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die
  60
  61         # make sure we use python2.* while using gyp
  62         sed -i -e "s/python/${EPYTHON}/" deps/npm/node_modules/node-gyp/gyp/gyp || die
  63         sed -i -e "s/|| 'python2'/|| '${EPYTHON}'/" deps/npm/node_modules/node-gyp/lib/configure.js || die
  64
  65         # less verbose install output (stating the same as portage, basically)
  66         sed -i -e "/print/d" tools/install.py || die
  67
  68         # proper libdir, hat tip @ryanpcmcquen https://github.com/iojs/io.js/issues/504
  69         local LIBDIR=$(get_libdir)
  70         sed -i -e "s|lib/|${LIBDIR}/|g" tools/install.py || die
  71         sed -i -e "s/'lib'/'${LIBDIR}'/" deps/npm/lib/npm.js || die
  72
  73         # Avoid writing a depfile, not useful
  74         sed -i -e "/DEPFLAGS =/d" tools/gyp/pylib/gyp/generator/make.py || die
  75
  76         sed -i -e "/'-O3'/d" common.gypi deps/v8/gypfiles/toolchain.gypi || die
  77
  78         # Avoid a test that I've only been able to reproduce from emerge. It doesnt
  79         # seem sandbox related either (invoking it from a sandbox works fine).
  80         # The issue is that no stdin handle is openened when asked for one.
  81         # It doesn't really belong upstream , so it'll just be removed until someone
  82         # with more gentoo-knowledge than me (jbergstroem) figures it out.
  83         rm test/parallel/test-stdout-close-unref.js || die
  84
  85         # debug builds. change install path, remove optimisations and override buildtype
  86         if use debug; then
  87                 sed -i -e "s|out/Release/|out/Debug/|g" tools/install.py || die
  88                 BUILDTYPE=Debug
  89         fi
  90
  91         default
  92 }
  93
  94 src_configure() {
  95         xdg_environment_reset
  96
  97         local myconf=( --shared-cares --shared-http-parser --shared-libuv --shared-nghttp2 --shared-zlib )
  98         use debug && myconf+=( --debug )
  99         use icu && myconf+=( --with-intl=system-icu ) || myconf+=( --with-intl=none )
 100         use inspector || myconf+=( --without-inspector )
 101         use npm || myconf+=( --without-npm )
 102         use snapshot && myconf+=( --with-snapshot )
 103         use ssl && myconf+=( --shared-openssl ) || myconf+=( --without-ssl )
 104
 105         local myarch=""
 106         case ${ABI} in
 107                 amd64) myarch="x64";;
 108                 arm) myarch="arm";;
 109                 arm64) myarch="arm64";;
 110                 ppc64) myarch="ppc64";;
 111                 x32) myarch="x32";;
 112                 x86) myarch="ia32";;
 113                 *) myarch="${ABI}";;
 114         esac
 115
 116         GYP_DEFINES="linux_use_gold_flags=0
 117                 linux_use_bundled_binutils=0
 118                 linux_use_bundled_gold=0" \
 119         "${PYTHON}" configure \
 120                 --prefix="${EPREFIX}"/usr \
 121                 --dest-cpu=${myarch} \
 122                 $(use_with systemtap dtrace) \
 123                 "${myconf[@]}" || die
 124 }
 125
 126 src_compile() {
 127         emake -C out mksnapshot
 128         pax-mark m "out/${BUILDTYPE}/mksnapshot"
 129         emake -C out
 130 }
 131
 132 src_install() {
 133         local LIBDIR="${ED}/usr/$(get_libdir)"
 134         emake install DESTDIR="${D}"
 135         pax-mark -m "${ED}"usr/bin/node
 136
 137         # set up a symlink structure that node-gyp expects..
 138         dodir /usr/include/node/deps/{v8,uv}
 139         dosym . /usr/include/node/src
 140         for var in deps/{uv,v8}/include; do
 141                 dosym ../.. /usr/include/node/${var}
 142         done
 143
 144         if use doc; then
 145                 # Patch docs to make them offline readable
 146                 for i in `grep -rl 'fonts.googleapis.com' "${S}"/out/doc/api/*`; do
 147                         sed -i '/fonts.googleapis.com/ d' $i;
 148                 done
 149                 # Install docs
 150                 docinto html
 151                 dodoc -r "${S}"/doc/*
 152         fi
 153
 154         if use npm; then
 155                 dodir /etc/npm
 156
 157                 # Install bash completion for `npm`
 158                 # We need to temporarily replace default config path since
 159                 # npm otherwise tries to write outside of the sandbox
 160                 local npm_config="usr/$(get_libdir)/node_modules/npm/lib/config/core.js"
 161                 sed -i -e "s|'/etc'|'${ED}/etc'|g" "${ED}/${npm_config}" || die
 162                 local tmp_npm_completion_file="$(emktemp)"
 163                 "${ED}/usr/bin/npm" completion > "${tmp_npm_completion_file}"
 164                 newbashcomp "${tmp_npm_completion_file}" npm
 165                 sed -i -e "s|'${ED}/etc'|'/etc'|g" "${ED}/${npm_config}" || die
 166
 167                 # Move man pages
 168                 doman "${LIBDIR}"/node_modules/npm/man/man{1,5,7}/*
 169
 170                 # Clean up
 171                 rm "${LIBDIR}"/node_modules/npm/{.mailmap,.npmignore,Makefile} || die
 172                 rm -rf "${LIBDIR}"/node_modules/npm/{doc,html,man} || die
 173
 174                 local find_exp="-or -name"
 175                 local find_name=()
 176                 for match in "AUTHORS*" "CHANGELOG*" "CONTRIBUT*" "README*" \
 177                         ".travis.yml" ".eslint*" ".wercker.yml" ".npmignore" \
 178                         "*.md" "*.markdown" "*.bat" "*.cmd"; do
 179                         find_name+=( ${find_exp} "${match}" )
 180                 done
 181
 182                 # Remove various development and/or inappropriate files and
 183                 # useless docs of dependend packages.
 184                 find "${LIBDIR}"/node_modules \
 185                         \( -type d -name examples \) -or \( -type f \( \
 186                                 -iname "LICEN?E*" \
 187                                 "${find_name[@]}" \
 188                         \) \) -exec rm -rf "{}" \;
 189         fi
 190
 191         mv "${D}"/usr/share/doc/node "${D}"/usr/share/doc/${PF} || die
 192 }
 193
 194 src_test() {
 195         out/${BUILDTYPE}/cctest || die
 196         "${PYTHON}" tools/test.py --mode=${BUILDTYPE,,} -J message parallel sequential || die
 197 }
 198
 199 pkg_postinst() {
 200         einfo "The global npm config lives in /etc/npm. This deviates slightly"
 201         einfo "from upstream which otherwise would have it live in /usr/etc/."
 202         einfo ""
 203         einfo "Protip: When using node-gyp to install native modules, you can"
 204         einfo "avoid having to download extras by doing the following:"
 205         einfo "$ node-gyp --nodedir /usr/include/node <command>"
 206 }