dev-java/netty-codec/netty-codec-4.0.36.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 MY_PN="netty"
  11 MY_P="${MY_PN}-${PV}"
  12 DESCRIPTION="Async event-driven framework for high performance network applications"
  13 HOMEPAGE="http://netty.io/"
  14 SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/${MY_P}.Final.tar.gz"
  15 LICENSE="Apache-2.0"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18 IUSE="test"
  19 RESTRICT="!test? ( test )"
  20
  21 CDEPEND="~dev-java/${MY_PN}-buffer-${PV}:0
  22         ~dev-java/${MY_PN}-common-${PV}:0
  23         ~dev-java/${MY_PN}-transport-${PV}:0
  24         dev-java/jboss-marshalling:0
  25         dev-java/jzlib:1.1.3
  26         dev-java/protobuf-java:0"
  27
  28 RDEPEND=">=virtual/jre-1.7
  29         ${CDEPEND}"
  30
  31 DEPEND=">=virtual/jdk-1.7
  32         ${CDEPEND}
  33         test? (
  34                 dev-java/hamcrest-core:1.3
  35                 dev-java/hamcrest-library:1.3
  36                 dev-java/jboss-marshalling-river:0
  37                 dev-java/jboss-marshalling-serial:0
  38                 dev-java/junit:4
  39         )"
  40
  41 S="${WORKDIR}/${MY_PN}-${MY_P}.Final/${PN/${MY_PN}-}"
  42 JAVA_SRC_DIR="src/main/java"
  43 JAVA_GENTOO_CLASSPATH="${MY_PN}-buffer,${MY_PN}-common,${MY_PN}-transport,jboss-marshalling,jzlib-1.1.3,protobuf-java"
  44
  45 src_test() {
  46         cd src/test/java || die
  47
  48         local CP=".:${S}/${PN}.jar:$(java-pkg_getjars --with-dependencies ${JAVA_GENTOO_CLASSPATH},hamcrest-core-1.3,hamcrest-library-1.3,jboss-marshalling-river,jboss-marshalling-serial,junit-4)"
  49         local TESTS=$(find * -name "*Test.java" ! -name "Abstract*" ! -name "ZlibTest*")
  50         TESTS="${TESTS//.java}"
  51         TESTS="${TESTS//\//.}"
  52
  53         ejavac -cp "${CP}" -d . $(find * -name "*.java")
  54         ejunit4 -classpath "${CP}" ${TESTS}
  55 }