dev-java/jdom/jdom-1.1.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 JAVA_PKG_IUSE="doc examples source"
   6
   7 inherit java-pkg-2 java-ant-2
   8
   9 DESCRIPTION="Java API to manipulate XML data"
  10 SRC_URI="http://www.jdom.org/dist/binary/archive/${P}.tar.gz"
  11 HOMEPAGE="http://www.jdom.org"
  12 LICENSE="JDOM"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm arm64 ppc64 x86"
  15 IUSE=""
  16
  17 RDEPEND=">=virtual/jre-1.6"
  18 DEPEND=">=virtual/jdk-1.6"
  19
  20 S="${WORKDIR}/${PN}"
  21
  22 java_prepare() {
  23         java-pkg_clean
  24
  25         rm -r build/apidocs || die
  26
  27         rm -v src/java/org/jdom/xpath/JaxenXPath.java \
  28                 || die "Unable to remove Jaxen Binding class."
  29
  30         sed -i -e 's|${name}-${version.impl}|${name}|g' \
  31                 -e 's|<jar jarfile="${build.dir}/${name}-sources|<!-- <jar jarfile="${build.dir}/${name}-sources|' \
  32                 -e 's|build.javadocs}" />|build.javadocs}" /> -->|' \
  33                 "${S}"/build.xml || die
  34
  35         if ! use doc; then
  36                 sed -i -e 's|depends="compile,javadoc"|depends="compile"|' \
  37                         "${S}"/build.xml || die
  38         fi
  39 }
  40
  41 EANT_BUILD_TARGET="package"
  42
  43 src_install() {
  44         java-pkg_dojar build/*.jar
  45         dodoc CHANGES.txt COMMITTERS.txt README.txt TODO.txt
  46         use doc && java-pkg_dojavadoc build/apidocs
  47         use examples && java-pkg_doexamples samples
  48         use source && java-pkg_dosrc src/java/org
  49 }