dev-java/ant-eclipse-ecj/ant-eclipse-ecj-4.5.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple prefix
   9
  10 DMF="R-${PV}-201509040015"
  11
  12 DESCRIPTION="Ant Compiler Adapter for Eclipse Java Compiler"
  13 HOMEPAGE="http://www.eclipse.org/"
  14 SRC_URI="http://download.eclipse.org/eclipse/downloads/drops4/${DMF}/ecjsrc-${PV}.jar"
  15
  16 LICENSE="EPL-1.0"
  17 KEYWORDS="amd64 ~ppc64 x86 ~amd64-linux ~x86-linux ~x86-solaris"
  18 SLOT="4.5"
  19 IUSE=""
  20
  21 CDEPEND="~dev-java/eclipse-ecj-${PV}:${SLOT}
  22         >=dev-java/ant-core-1.7"
  23 RDEPEND="${CDEPEND}
  24         >=virtual/jre-1.7"
  25 DEPEND="${CDEPEND}
  26         app-arch/unzip
  27         >=virtual/jdk-1.7"
  28
  29 JAVA_GENTOO_CLASSPATH="ant-core,eclipse-ecj-${SLOT}"
  30
  31 java_prepare() {
  32         # Remove everything but the Ant component.
  33         find org -type f ! -path "org/eclipse/jdt/internal/antadapter/*" ! -name "JDTCompilerAdapter.java" -delete || die
  34
  35         rm build.xml || die
  36 }
  37
  38 src_compile() {
  39         java-pkg-simple_src_compile
  40         find org -type f ! -name "*.java" | xargs jar uvf "${PN}.jar" || die "jar update failed"
  41 }
  42
  43 src_install() {
  44         java-pkg-simple_src_install
  45         insinto /usr/share/java-config-2/compiler
  46         doins "${FILESDIR}/ecj-${SLOT}"
  47         eprefixify "${D}"/usr/share/java-config-2/compiler/ecj-${SLOT}
  48 }