configure.ac

   1
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([comedi/comedi_fops.c])
   4 AC_CONFIG_HEADERS(config.h)
   5
   6 AC_CANONICAL_TARGET([])
   7
   8 if test x$prefix = xNONE ; then
   9   prefix=/
  10 fi
  11
  12 PACKAGE=comedi
  13 COMEDI_MAJORVERSION=0
  14 COMEDI_MINORVERSION=7
  15 COMEDI_MICROVERSION=72
  16 # set the nanoversion to 0 for releases, 1 for CVS, >= 2 for prereleases
  17 COMEDI_NANOVERSION=0
  18
  19 if test x$COMEDI_NANOVERSION = x0 ; then
  20   VERSION=$COMEDI_MAJORVERSION.$COMEDI_MINORVERSION.$COMEDI_MICROVERSION
  21 else
  22   VERSION=$COMEDI_MAJORVERSION.$COMEDI_MINORVERSION.$COMEDI_MICROVERSION.$COMEDI_NANOVERSION
  23 fi
  24
  25 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  26 AM_MAINTAINER_MODE
  27
  28 AC_SUBST(PACKAGE)
  29 AC_SUBST(VERSION)
  30 AC_DEFINE_UNQUOTED(COMEDI_MAJORVERSION, $COMEDI_MAJORVERSION, [Comedi major version])
  31 AC_DEFINE_UNQUOTED(COMEDI_MINORVERSION, $COMEDI_MINORVERSION, [Comedi minor version])
  32 AC_DEFINE_UNQUOTED(COMEDI_MICROVERSION, $COMEDI_MICROVERSION, [Comedi micro version])
  33
  34 AC_PROG_CC()
  35 AC_PATH_TOOL([STRIP],[strip])
  36 AC_PATH_PROG([DEPMOD], [depmod], [no], [$PATH:/sbin:/usr/sbin:/usr/local/sbin])
  37 if test "$DEPMOD" == "no" ; then
  38         AC_MSG_ERROR([unable to find the 'depmod' program.])
  39 fi
  40
  41 AS_LINUX()
  42 AS_LINUX_MODTOOL()
  43
  44 AC_ARG_ENABLE([rtai], [  --disable-rtai disable use of rtai],
  45         [ENABLE_RTAI=$enableval], [ENABLE_RTAI="yes"])
  46 DS_RTAI([HAVE_RTAI=yes],[HAVE_RTAI=no])
  47 if test "$HAVE_RTAI" == "yes" -a "$ENABLE_RTAI" == "yes"; then
  48         USE_RTAI="yes"
  49 else
  50         USE_RTAI="no"
  51 fi
  52 DS_RTLINUX([USE_RTLINUX=yes],[USE_RTLINUX=no])
  53 AM_CONDITIONAL([CONFIG_COMEDI_RT],
  54         [test ${USE_RTAI} = "yes" -o ${USE_RTLINUX} = "yes"])
  55 if test ${USE_RTAI} = "yes" -o ${USE_RTLINUX} = "yes" ; then
  56         AC_DEFINE([CONFIG_COMEDI_RT],[true],[Define to enable Comedi's real-time support])
  57 fi
  58
  59
  60 CC=$LINUX_CC
  61
  62 #ERROR_CFLAGS="-Werror"
  63
  64 [COMEDI_CFLAGS="$ERROR_CFLAGS -I\$(top_srcdir)/include/\
  65  -DKBUILD_MODNAME=\$(shell basename \$@ .o | sed 's/\(.*\)_ko.*/\1/g')\
  66  -DKBUILD_BASENAME=\$(shell basename \$< .c)"]
  67 AC_SUBST(COMEDI_CFLAGS)
  68
  69 COMEDI_CHECK_PCMCIA_PROBE([$LINUX_DIR], [ENABLE_PCMCIA="yes"], [ENABLE_PCMCIA="no"])
  70 AC_ARG_ENABLE([pcmcia],[  --disable-pcmcia      Disable support for PCMCIA devices],
  71         [ENABLE_PCMCIA=$enableval],[])
  72 if test "$ENABLE_PCMCIA" = "yes" ; then
  73         AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_PCMCIA)
  74 else
  75         AC_MSG_NOTICE([PCMCIA support disabled])
  76         AM_CONDITIONAL(CONFIG_PCMCIA,false)
  77 fi
  78 AC_ARG_ENABLE([usb],[  --disable-usb            Disable support for USB devices],
  79         [ENABLE_USB=$enableval],[ENABLE_USB="yes"])
  80 if test "$ENABLE_USB" = "yes" ; then
  81         AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_USB)
  82 else
  83         AC_MSG_NOTICE([USB support disabled])
  84         AM_CONDITIONAL(CONFIG_USB,false)
  85 fi
  86 COMEDI_CHECK_LINUX_KBUILD([$LINUX_DIR], [ENABLE_KBUILD="yes"], [ENABLE_KBUILD="no"])
  87 AC_ARG_ENABLE([kbuild], [  --enable-kbuild      Force use (or not) of kernel's Kbuild system to build modules (needs recent 2.6 kernel)],
  88         [ENABLE_KBUILD=$enableval], [])
  89 AM_CONDITIONAL([CONFIG_KBUILD], [test ${ENABLE_KBUILD} = "yes"])
  90 AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_ISA)
  91 AS_LINUX_CONFIG_OPTION_MODULE(CONFIG_PCI)
  92
  93 AC_DEFINE(CONFIG_COMEDI_DEBUG, true, [Define if debugging is enabled])
  94 AC_DEFINE(CONFIG_COMEDI_8255, true, [Define if 8255 support is enabled])
  95
  96 DISTCHECK_CONFIGURE_FLAGS="--with-modulesdir=\\\$\$\(prefix\)/modules"
  97 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
  98
  99 AC_CONFIG_FILES([
 100 Makefile
 101 comedi/Makefile
 102 comedi/drivers/Makefile
 103 comedi/drivers/addi-data/Makefile
 104 comedi/kcomedilib/Makefile
 105 ])
 106 AC_OUTPUT
 107