IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Blog aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8 use HTML::Entities;
   9 use HTML::Parser;
  10 use HTML::Tagset;
  11 use URI;
  12 use open qw{:utf8 :std};
  13
  14 my %feeds;
  15 my %guids;
  16
  17 sub import { #{{{
  18         hook(type => "getopt", id => "aggregate", call => \&getopt);
  19         hook(type => "checkconfig", id => "aggregate", call => \&checkconfig);
  20         hook(type => "filter", id => "aggregate", call => \&filter);
  21         hook(type => "preprocess", id => "aggregate", call => \&preprocess);
  22         hook(type => "delete", id => "aggregate", call => \&delete);
  23         hook(type => "savestate", id => "aggregate", call => \&savestate);
  24 } # }}}
  25
  26 sub getopt () { #{{{
  27         eval q{use Getopt::Long};
  28         error($@) if $@;
  29         Getopt::Long::Configure('pass_through');
  30         GetOptions("aggregate" => \$config{aggregate});
  31 } #}}}
  32
  33 sub checkconfig () { #{{{
  34         if ($config{aggregate} && ! ($config{post_commit} &&
  35                                      IkiWiki::commit_hook_enabled())) {
  36                 # don't wait for the lock
  37                 IkiWiki::lockwiki(0) || exit 1;
  38
  39                 loadstate();
  40                 IkiWiki::loadindex();
  41                 aggregate();
  42                 expire();
  43                 savestate();
  44
  45                 IkiWiki::unlockwiki();
  46         }
  47 } #}}}
  48
  49 sub filter (@) { #{{{
  50         my %params=@_;
  51         my $page=$params{page};
  52
  53         loadstate(); # if not already loaded
  54         # Mark all feeds originating on this page as removable;
  55         # preprocess will unmark those that still exist.
  56         remove_feeds($page);
  57
  58         return $params{content};
  59 } # }}}
  60
  61 sub preprocess (@) { #{{{
  62         my %params=@_;
  63
  64         foreach my $required (qw{name url}) {
  65                 if (! exists $params{$required}) {
  66                         return "[[aggregate ".sprintf(gettext("missing %s parameter"), $required)."]]";
  67                 }
  68         }
  69
  70         my $feed={};
  71         my $name=$params{name};
  72         if (exists $feeds{$name}) {
  73                 $feed=$feeds{$name};
  74         }
  75         else {
  76                 $feeds{$name}=$feed;
  77         }
  78         $feed->{name}=$name;
  79         $feed->{sourcepage}=$params{page};
  80         $feed->{url}=$params{url};
  81         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
  82         $dir=~s/^\/+//;
  83         ($dir)=$dir=~/$config{wiki_file_regexp}/;
  84         $feed->{dir}=$dir;
  85         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
  86         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
  87         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
  88         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
  89         delete $feed->{remove};
  90         delete $feed->{expired};
  91         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
  92         $feed->{numposts}=0 unless defined $feed->{numposts};
  93         $feed->{newposts}=0 unless defined $feed->{newposts};
  94         $feed->{message}=gettext("new feed") unless defined $feed->{message};
  95         $feed->{error}=0 unless defined $feed->{error};
  96         $feed->{tags}=[];
  97         while (@_) {
  98                 my $key=shift;
  99                 my $value=shift;
 100                 if ($key eq 'tag') {
 101                         push @{$feed->{tags}}, $value;
 102                 }
 103         }
 104
 105         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
 106                ($feed->{error} ? "<em>" : "").$feed->{message}.
 107                ($feed->{error} ? "</em>" : "").
 108                " (".$feed->{numposts}." ".gettext("posts").
 109                ($feed->{newposts} ? "; ".$feed->{newposts}.
 110                                     " ".gettext("new") : "").
 111                ")";
 112 } # }}}
 113
 114 sub delete (@) { #{{{
 115         my @files=@_;
 116
 117         # Remove feed data for removed pages.
 118         foreach my $file (@files) {
 119                 my $page=pagename($file);
 120                 remove_feeds($page);
 121         }
 122 } #}}}
 123
 124 my $state_loaded=0;
 125 sub loadstate () { #{{{
 126         return if $state_loaded;
 127         if (-e "$config{wikistatedir}/aggregate") {
 128                 open (IN, "$config{wikistatedir}/aggregate" ||
 129                         die "$config{wikistatedir}/aggregate: $!");
 130                 while (<IN>) {
 131                         $_=IkiWiki::possibly_foolish_untaint($_);
 132                         chomp;
 133                         my $data={};
 134                         foreach my $i (split(/ /, $_)) {
 135                                 my ($field, $val)=split(/=/, $i, 2);
 136                                 if ($field eq "name" || $field eq "feed" ||
 137                                     $field eq "guid" || $field eq "message") {
 138                                         $data->{$field}=decode_entities($val, " \t\n");
 139                                 }
 140                                 elsif ($field eq "tag") {
 141                                         push @{$data->{tags}}, $val;
 142                                 }
 143                                 else {
 144                                         $data->{$field}=$val;
 145                                 }
 146                         }
 147
 148                         if (exists $data->{name}) {
 149                                 $feeds{$data->{name}}=$data;
 150                         }
 151                         elsif (exists $data->{guid}) {
 152                                 $guids{$data->{guid}}=$data;
 153                         }
 154                 }
 155
 156                 close IN;
 157
 158                 $state_loaded=1;
 159         }
 160 } #}}}
 161
 162 sub savestate () { #{{{
 163         eval q{use HTML::Entities};
 164         error($@) if $@;
 165         my $newfile="$config{wikistatedir}/aggregate.new";
 166         # TODO: This cleanup function could use improvement. Any newly
 167         # aggregated files are left behind unrecorded, and should be deleted.
 168         my $cleanup = sub { unlink($newfile) };
 169         open (OUT, ">$newfile") || error("open $newfile: $!", $cleanup);
 170         foreach my $data (values %feeds, values %guids) {
 171                 if ($data->{remove}) {
 172                         if ($data->{name}) {
 173                                 foreach my $guid (values %guids) {
 174                                         if ($guid->{feed} eq $data->{name}) {
 175                                                 $guid->{remove}=1;
 176                                         }
 177                                 }
 178                         }
 179                         else {
 180                                 unlink pagefile($data->{page});
 181                         }
 182                         next;
 183                 }
 184                 elsif ($data->{expired} && exists $data->{page}) {
 185                         unlink pagefile($data->{page});
 186                         delete $data->{page};
 187                         delete $data->{md5};
 188                 }
 189
 190                 my @line;
 191                 foreach my $field (keys %$data) {
 192                         if ($field eq "name" || $field eq "feed" ||
 193                             $field eq "guid" || $field eq "message") {
 194                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 195                         }
 196                         elsif ($field eq "tags") {
 197                                 push @line, "tag=$_" foreach @{$data->{tags}};
 198                         }
 199                         else {
 200                                 push @line, "$field=".$data->{$field};
 201                         }
 202                 }
 203                 print OUT join(" ", @line)."\n" || error("write $newfile: $!", $cleanup);
 204         }
 205         close OUT || error("save $newfile: $!", $cleanup);
 206         rename($newfile, "$config{wikistatedir}/aggregate") ||
 207                 error("rename $newfile: $!", $cleanup);
 208 } #}}}
 209
 210 sub expire () { #{{{
 211         foreach my $feed (values %feeds) {
 212                 next unless $feed->{expireage} || $feed->{expirecount};
 213                 my $count=0;
 214                 foreach my $item (sort { $IkiWiki::pagectime{$b->{page}} <=> $IkiWiki::pagectime{$a->{page}} }
 215                                   grep { exists $_->{page} && $_->{feed} eq $feed->{name} && $IkiWiki::pagectime{$_->{page}} }
 216                                   values %guids) {
 217                         if ($feed->{expireage}) {
 218                                 my $days_old = (time - $IkiWiki::pagectime{$item->{page}}) / 60 / 60 / 24;
 219                                 if ($days_old > $feed->{expireage}) {
 220                                         debug(sprintf(gettext("expiring %s (%s days old)"),
 221                                                 $item->{page}, $days_old));
 222                                         $item->{expired}=1;
 223                                 }
 224                         }
 225                         elsif ($feed->{expirecount} &&
 226                                $count >= $feed->{expirecount}) {
 227                                 debug(sprintf(gettext("expiring %s"), $item->{page}));
 228                                 $item->{expired}=1;
 229                         }
 230                         else {
 231                                 $count++;
 232                         }
 233                 }
 234         }
 235 } #}}}
 236
 237 sub aggregate () { #{{{
 238         eval q{use XML::Feed};
 239         error($@) if $@;
 240         eval q{use URI::Fetch};
 241         error($@) if $@;
 242         eval q{use HTML::Entities};
 243         error($@) if $@;
 244
 245         foreach my $feed (values %feeds) {
 246                 next unless $config{rebuild} ||
 247                         time - $feed->{lastupdate} >= $feed->{updateinterval};
 248                 $feed->{lastupdate}=time;
 249                 $feed->{newposts}=0;
 250                 $feed->{message}=sprintf(gettext("processed ok at %s"),
 251                         displaytime($feed->{lastupdate}));
 252                 $feed->{error}=0;
 253                 $IkiWiki::forcerebuild{$feed->{sourcepage}}=1;
 254
 255                 debug(sprintf(gettext("checking feed %s ..."), $feed->{name}));
 256
 257                 if (! length $feed->{feedurl}) {
 258                         my @urls=XML::Feed->find_feeds($feed->{url});
 259                         if (! @urls) {
 260                                 $feed->{message}=sprintf(gettext("could not find feed at %s"), $feed->{url});
 261                                 $feed->{error}=1;
 262                                 debug($feed->{message});
 263                                 next;
 264                         }
 265                         $feed->{feedurl}=pop @urls;
 266                 }
 267                 my $res=URI::Fetch->fetch($feed->{feedurl});
 268                 if (! $res) {
 269                         $feed->{message}=URI::Fetch->errstr;
 270                         $feed->{error}=1;
 271                         debug($feed->{message});
 272                         next;
 273                 }
 274                 if ($res->status == URI::Fetch::URI_GONE()) {
 275                         $feed->{message}=gettext("feed not found");
 276                         $feed->{error}=1;
 277                         debug($feed->{message});
 278                         next;
 279                 }
 280                 my $content=$res->content;
 281                 my $f=eval{XML::Feed->parse(\$content)};
 282                 if ($@) {
 283                         # One common cause of XML::Feed crashing is a feed
 284                         # that contains invalid UTF-8 sequences. Convert
 285                         # feed to ascii to try to work around.
 286                         $feed->{message}.=" ".sprintf(gettext("(invalid UTF-8 stripped from feed)"));
 287                         $content=Encode::decode_utf8($content);
 288                         $f=eval{XML::Feed->parse(\$content)};
 289                 }
 290                 if ($@) {
 291                         $feed->{message}=gettext("feed crashed XML::Feed!")." ($@)";
 292                         $feed->{error}=1;
 293                         debug($feed->{message});
 294                         next;
 295                 }
 296                 if (! $f) {
 297                         $feed->{message}=XML::Feed->errstr;
 298                         $feed->{error}=1;
 299                         debug($feed->{message});
 300                         next;
 301                 }
 302
 303                 foreach my $entry ($f->entries) {
 304                         add_page(
 305                                 feed => $feed,
 306                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 307                                 link => $entry->link,
 308                                 content => defined $entry->content->body ? $entry->content->body : "",
 309                                 guid => defined $entry->id ? $entry->id : time."_".$feed->name,
 310                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 311                         );
 312                 }
 313         }
 314 } #}}}
 315
 316 sub add_page (@) { #{{{
 317         my %params=@_;
 318
 319         my $feed=$params{feed};
 320         my $guid={};
 321         my $mtime;
 322         if (exists $guids{$params{guid}}) {
 323                 # updating an existing post
 324                 $guid=$guids{$params{guid}};
 325                 return if $guid->{expired};
 326         }
 327         else {
 328                 # new post
 329                 $guid->{guid}=$params{guid};
 330                 $guids{$params{guid}}=$guid;
 331                 $mtime=$params{ctime};
 332                 $feed->{numposts}++;
 333                 $feed->{newposts}++;
 334
 335                 # assign it an unused page
 336                 my $page=IkiWiki::titlepage($params{title});
 337                 # escape slashes and periods in title so it doesn't specify
 338                 # directory name or trigger ".." disallowing code.
 339                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 340                 $page=$feed->{dir}."/".$page;
 341                 ($page)=$page=~/$config{wiki_file_regexp}/;
 342                 if (! defined $page || ! length $page) {
 343                         $page=$feed->{dir}."/item";
 344                 }
 345                 my $c="";
 346                 while (exists $IkiWiki::pagecase{lc $page.$c} ||
 347                        -e pagefile($page.$c)) {
 348                         $c++
 349                 }
 350
 351                 # Make sure that the file name isn't too long.
 352                 # NB: This doesn't check for path length limits.
 353                 my $max=POSIX::pathconf($config{srcdir}, &POSIX::_PC_NAME_MAX);
 354                 if (defined $max && length(htmlfn($page)) >= $max) {
 355                         $c="";
 356                         $page=$feed->{dir}."/item";
 357                         while (exists $IkiWiki::pagecase{lc $page.$c} ||
 358                                -e pagefile($page.$c)) {
 359                                 $c++
 360                         }
 361                 }
 362
 363                 $guid->{page}=$page;
 364                 debug(sprintf(gettext("creating new page %s"), $page));
 365         }
 366         $guid->{feed}=$feed->{name};
 367
 368         # To write or not to write? Need to avoid writing unchanged pages
 369         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 370         # trusted; let's use a digest.
 371         eval q{use Digest::MD5 'md5_hex'};
 372         error($@) if $@;
 373         require Encode;
 374         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 375         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $config{rebuild};
 376         $guid->{md5}=$digest;
 377
 378         # Create the page.
 379         my $template=template("aggregatepost.tmpl", blind_cache => 1);
 380         $template->param(title => $params{title})
 381                 if defined $params{title} && length($params{title});
 382         $template->param(content => htmlescape(htmlabs($params{content}, $feed->{feedurl})));
 383         $template->param(name => $feed->{name});
 384         $template->param(url => $feed->{url});
 385         $template->param(permalink => urlabs($params{link}, $feed->{feedurl}))
 386                 if defined $params{link};
 387         if (ref $feed->{tags}) {
 388                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 389         }
 390         writefile(htmlfn($guid->{page}), $config{srcdir},
 391                 $template->output);
 392
 393         # Set the mtime, this lets the build process get the right creation
 394         # time on record for the new page.
 395         utime $mtime, $mtime, pagefile($guid->{page}) if defined $mtime;
 396 } #}}}
 397
 398 sub htmlescape ($) { #{{{
 399         # escape accidental wikilinks and preprocessor stuff
 400         my $html=shift;
 401         $html=~s/(?<!\\)\[\[/\\\[\[/g;
 402         return $html;
 403 } #}}}
 404
 405 sub urlabs ($$) { #{{{
 406         my $url=shift;
 407         my $urlbase=shift;
 408
 409         URI->new_abs($url, $urlbase)->as_string;
 410 } #}}}
 411
 412 sub htmlabs ($$) { #{{{
 413         # Convert links in html from relative to absolute.
 414         # Note that this is a heuristic, which is not specified by the rss
 415         # spec and may not be right for all feeds. Also, see Debian
 416         # bug #381359.
 417         my $html=shift;
 418         my $urlbase=shift;
 419
 420         my $ret="";
 421         my $p = HTML::Parser->new(api_version => 3);
 422         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 423         $p->handler(start => sub {
 424                 my ($tagname, $pos, $text) = @_;
 425                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 426                         while (4 <= @$pos) {
 427                                 # use attribute sets from right to left
 428                                 # to avoid invalidating the offsets
 429                                 # when replacing the values
 430                                 my($k_offset, $k_len, $v_offset, $v_len) =
 431                                         splice(@$pos, -4);
 432                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 433                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 434                                 next unless $v_offset; # 0 v_offset means no value
 435                                 my $v = substr($text, $v_offset, $v_len);
 436                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 437                                 my $new_v=urlabs($v, $urlbase);
 438                                 $new_v =~ s/\"/&quot;/g; # since we quote with ""
 439                                 substr($text, $v_offset, $v_len) = qq("$new_v");
 440                         }
 441                 }
 442                 $ret.=$text;
 443         }, "tagname, tokenpos, text");
 444         $p->parse($html);
 445         $p->eof;
 446
 447         return $ret;
 448 } #}}}
 449
 450 sub remove_feeds () { #{{{
 451         my $page=shift;
 452
 453         my %removed;
 454         foreach my $id (keys %feeds) {
 455                 if ($feeds{$id}->{sourcepage} eq $page) {
 456                         $feeds{$id}->{remove}=1;
 457                         $removed{$id}=1;
 458                 }
 459         }
 460 } #}}}
 461
 462 sub pagefile ($) { #{{{
 463         my $page=shift;
 464
 465         return "$config{srcdir}/".htmlfn($page);
 466 } #}}}
 467
 468 sub htmlfn ($) { #{{{
 469         return shift().".html";
 470 } #}}}
 471
 472 1