From d91c9bba80c45e0f75fc77439c19d6b01dc41ab7 Mon Sep 17 00:00:00 2001
From: Doug Goldstein <cardoe@gentoo.org>
Date: Wed, 9 Nov 2011 15:58:15 +0000
Subject: [PATCH] Version bump

Package-Manager: portage-2.1.10.32/cvs/Linux x86_64
---
 app-emulation/libvirt/ChangeLog            |   7 +-
 app-emulation/libvirt/Manifest             |   4 +-
 app-emulation/libvirt/libvirt-0.9.7.ebuild | 265 +++++++++++++++++++++
 3 files changed, 274 insertions(+), 2 deletions(-)
 create mode 100644 app-emulation/libvirt/libvirt-0.9.7.ebuild

diff --git a/app-emulation/libvirt/ChangeLog b/app-emulation/libvirt/ChangeLog
index 4667fee465dd..82899b6710d2 100644
--- a/app-emulation/libvirt/ChangeLog
+++ b/app-emulation/libvirt/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.137 2011/10/27 18:57:28 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.138 2011/11/09 15:58:15 cardoe Exp $
+
+*libvirt-0.9.7 (09 Nov 2011)
+
+  09 Nov 2011; Doug Goldstein <cardoe@gentoo.org> +libvirt-0.9.7.ebuild:
+  Version bump
 
   27 Oct 2011; Doug Goldstein <cardoe@gentoo.org> libvirt-0.9.3-r1.ebuild,
   libvirt-0.9.4.ebuild, libvirt-0.9.6.ebuild, libvirt-9999.ebuild:
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index 6f589a039969..7ccd393cfa7f 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -9,9 +9,11 @@ DIST libvirt-0.9.3-backports-2.tar.bz2 2165 RMD160 445a2391fa10b76160ecb1d1d80ea
 DIST libvirt-0.9.3.tar.gz 15958983 RMD160 a01dbe29e23225706afcff74146aa3b224ba04bb SHA1 e25850d270a24441305dd92935209efa993b479d SHA256 4d673be9aa7b5618c0fef3cfdbbbeff02df1c83e26680fe40defad2b32a56ae3
 DIST libvirt-0.9.4.tar.gz 16643543 RMD160 a9edfdac715caac650520e5e12dd499f46e9957b SHA1 29e81c972ca7c3e73f4cecf84e77f68739ef00a2 SHA256 e76c026646ae4885b162bf711b854f36195f93538d6fcbee48479c2354a342af
 DIST libvirt-0.9.6.tar.gz 17326676 RMD160 5e0837e8ee770e017e574fd002e9e489e448ca65 SHA1 9fd108e1a351d191c5d7f89458096fb35bd6413e SHA256 ce29b1cd3067b224aa834fec2a93d7613c0e72bc035760ad536a2142430bc02b
+DIST libvirt-0.9.7.tar.gz 17853636 RMD160 d5a9e7461fc2c487aadf7e8955a213252edd1e2e SHA1 2f08609267154ad5377b3dc3952eb1e77469b570 SHA256 29ff05bfe5177d6680c02c279ed2573dcfae993f2824bffa192a3a2cdd05af23
 EBUILD libvirt-0.9.3-r1.ebuild 7737 RMD160 b0b705ccca86b210cfc7d5edf85598293bf18899 SHA1 b57290a3779ebbf860c8d956641bdf75d211ca0f SHA256 4c092f4c6d57b127199dad40985bd98acc9607beda92b644c3069b5c60f98d16
 EBUILD libvirt-0.9.4.ebuild 7878 RMD160 c514dc4531ce263f9fdedf28314844908c96fe76 SHA1 8066a9146d9c2ea8615daaa356ef52c30a1bdff0 SHA256 692ab87250ba25a49c161eb1f2aca9266bf6062eed20d822664331d93e76652b
 EBUILD libvirt-0.9.6.ebuild 7878 RMD160 b2d89a590da15fb1993204cf5fad010e38d6263d SHA1 d16a10aadd0dd1e4cb6835c979d9735f1ed2da12 SHA256 c35c965cd2c89f92330789411826b605cfe1727403f07296dff3da679a5b33d6
+EBUILD libvirt-0.9.7.ebuild 7878 RMD160 998a7a3a11b954ab1f72eca400c22d9a6019279e SHA1 55530ccfcc696649a4403fcd1d5721fafae34086 SHA256 df01e992eb46401293137f1d100d4b49a84aa0d5b723c8e214ac6f63ced49b14
 EBUILD libvirt-9999.ebuild 7878 RMD160 d24a6ba66653b0856ba513997c228f42d8b74dab SHA1 41cda5aa50fffa8be6ea51b1c332f08ab79f85c6 SHA256 69c221285995cccbe43d603fa3ab897b12c37345276a6e97a7a8ea9d113787af
-MISC ChangeLog 28924 RMD160 b6e48f787118ea24cc26fed5931cf44a0a195b55 SHA1 15e9d7e19e50ba156438de6cb920d969bccfb191 SHA256 7488e60936cfea69544f8e8cdd5678f531b47eedd7c31d64fd0e9341f48ed9ae
+MISC ChangeLog 29043 RMD160 6353a307678049a5d0bde70671373e4272a095e4 SHA1 cbe24f3de7fbdc96c681e4f343b739f8682d8b42 SHA256 62034b14fd0f861c8bf240c9679f50a55b26d9df339b2210729b5f2b33c27eb5
 MISC metadata.xml 3132 RMD160 066870c02fd835f9a633b69328367737d4cc0b71 SHA1 940cc910ef4d1a75947afef95d73a3026bb91527 SHA256 e0eb882799f41f51c9930a1142cf5427061bdacf629a028ac4e8b65c1cf67ea4
diff --git a/app-emulation/libvirt/libvirt-0.9.7.ebuild b/app-emulation/libvirt/libvirt-0.9.7.ebuild
new file mode 100644
index 000000000000..3649f568068e
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-0.9.7.ebuild
@@ -0,0 +1,265 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.9.7.ebuild,v 1.1 2011/11/09 15:58:15 cardoe Exp $
+
+#BACKPORTS=2
+#AUTOTOOLIZE=yes
+
+EAPI="3"
+
+MY_P="${P/_rc/-rc}"
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="git://libvirt.org/libvirt.git"
+	GIT_ECLASS="git-2"
+	AUTOTOOLIZE=yes
+fi
+
+PYTHON_DEPEND="python? 2:2.4"
+#RESTRICT_PYTHON_ABIS="3.*"
+#SUPPORT_PYTHON_ABIS="1"
+
+inherit eutils python ${AUTOTOOLIZE+autotools} ${GIT_ECLASS}
+
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://libvirt.org/sources/${MY_P}.tar.gz
+		ftp://libvirt.org/libvirt/${MY_P}.tar.gz
+		${BACKPORTS:+
+			http://dev.gentoo.org/~flameeyes/${PN}/${MY_P}-backports-${BACKPORTS}.tar.bz2
+			http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-backports-${BACKPORTS}.tar.bz2}"
+	KEYWORDS="~amd64 ~x86"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="http://www.libvirt.org/"
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="avahi caps debug iscsi +json +libvirtd lvm +lxc macvtap nfs \
+	nls numa openvz parted pcap phyp policykit python qemu sasl selinux udev \
+	uml virtualbox virt-network xen elibc_glibc"
+# IUSE=one : bug #293416 & bug #299011
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+RDEPEND="sys-libs/readline
+	sys-libs/ncurses
+	>=net-misc/curl-7.18.0
+	>=dev-libs/libxml2-2.7.6
+	>=dev-libs/libnl-1.1:1.1
+	>=net-libs/gnutls-1.0.25
+	>=sys-apps/util-linux-2.17
+	sys-devel/gettext
+	>=net-analyzer/netcat6-1.0-r2
+	avahi? ( >=net-dns/avahi-0.6[dbus] )
+	caps? ( sys-libs/libcap-ng )
+	iscsi? ( sys-block/open-iscsi )
+	json? ( dev-libs/yajl )
+	libvirtd? ( net-misc/bridge-utils )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
+	nfs? ( net-fs/nfs-utils )
+	numa? ( >sys-process/numactl-2.0.2 )
+	openvz? ( sys-kernel/openvz-sources )
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2
+	)
+	pcap? ( >=net-libs/libpcap-1.0.0 )
+	phyp? ( net-libs/libssh2 )
+	policykit? ( >=sys-auth/polkit-0.9 )
+	qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 ) )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virtualbox? ( || ( app-emulation/virtualbox >=app-emulation/virtualbox-bin-2.2.0 ) )
+	xen? ( app-emulation/xen-tools app-emulation/xen )
+	udev? ( >=sys-fs/udev-145 >=x11-libs/libpciaccess-0.10.9 )
+	virt-network? ( net-dns/dnsmasq
+		>=net-firewall/iptables-1.4.10
+		net-firewall/ebtables
+		sys-apps/iproute2 )
+	elibc_glibc? ( || ( >=net-libs/libtirpc-0.2.2-r1 <sys-libs/glibc-2.14 ) )"
+# one? ( dev-libs/xmlrpc-c )
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	[[ -n ${BACKPORTS} ]] && \
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+			epatch
+
+	[[ -n ${AUTOTOOLIZE} ]] && eautoreconf
+}
+
+src_configure() {
+	local myconf=""
+
+	myconf="${myconf} $(use_enable debug)"
+
+	## enable/disable daemon, otherwise client only utils
+	myconf="${myconf} $(use_with libvirtd)"
+
+	## enable/disable the daemon using avahi to find VMs
+	myconf="${myconf} $(use_with avahi)"
+
+	## hypervisors on the local host
+	myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
+	 # leave it automagic as it depends on the version of xen used.
+	use xen || myconf+=" --without-libxl"
+
+	myconf="${myconf} $(use_with openvz)"
+	myconf="${myconf} $(use_with lxc)"
+	if use virtualbox && has_version app-emulation/virtualbox-ose; then
+		myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
+	else
+		myconf="${myconf} $(use_with virtualbox vbox)"
+	fi
+	myconf="${myconf} $(use_with uml)"
+	myconf="${myconf} $(use_with qemu)"
+	# doesn't belong with hypervisors but links to libvirtd for some reason
+	#myconf="${myconf} $(use_with one)"
+
+	## hypervisor protocols
+	myconf="${myconf} $(use_with phyp)"
+	myconf="${myconf} --with-esx"
+
+	## additional host drivers
+	myconf="${myconf} $(use_with virt-network network)"
+	myconf="${myconf} --with-storage-fs"
+	myconf="${myconf} $(use_with lvm storage-lvm)"
+	myconf="${myconf} $(use_with iscsi storage-iscsi)"
+	myconf="${myconf} $(use_with parted storage-disk)"
+	myconf="${myconf} $(use_with lvm storage-mpath)"
+	myconf="${myconf} $(use_with numa numactl)"
+	myconf="${myconf} $(use_with selinux)"
+
+	# udev for device support details
+	myconf="${myconf} $(use_with udev)"
+
+	# linux capability support so we don't need privileged accounts
+	myconf="${myconf} $(use_with caps capng)"
+
+	## auth stuff
+	myconf="${myconf} $(use_with policykit polkit)"
+	myconf="${myconf} $(use_with sasl)"
+
+	# network bits
+	myconf="${myconf} $(use_with macvtap)"
+	myconf="${myconf} $(use_with pcap libpcap)"
+
+	## other
+	myconf="${myconf} $(use_enable nls)"
+	myconf="${myconf} $(use_with python)"
+	myconf="${myconf} $(use_with json yajl)"
+
+	## stuff we don't yet support
+	myconf="${myconf} --without-netcf --without-audit"
+
+	# we use udev over hal
+	myconf="${myconf} --without-hal"
+
+	# locking support
+	myconf="${myconf} --without-sanlock"
+
+	# this is a nasty trick to work around the problem in bug
+	# #275073. The reason why we don't solve this properly is that
+	# it'll require us to rebuild autotools (and we don't really want
+	# to do that right now). The proper solution has been sent
+	# upstream and should hopefully land in 0.7.7, in the mean time,
+	# mime the same functionality with this.
+	case ${CHOST} in
+		*cygwin* | *mingw* )
+			;;
+		*)
+			ac_cv_prog_WINDRES=no
+			;;
+	esac
+
+	econf \
+		${myconf} \
+		--disable-static \
+		--docdir=/usr/share/doc/${PF} \
+		--with-remote \
+		--localstatedir=/var
+}
+
+src_test() {
+	# Explicitly allow parallel build of tests
+	HOME="${T}" emake check || die "tests failed"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		HTML_DIR=/usr/share/doc/${PF}/html \
+		DOCS_DIR=/usr/share/doc/${PF}/python \
+		EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
+		|| die "emake install failed"
+
+	find "${D}" -name '*.la' -delete || die
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	newinitd "${FILESDIR}/libvirtd.init-r5" libvirtd || die
+	newconfd "${FILESDIR}/libvirtd.confd-r2" libvirtd || die
+
+	keepdir /var/lib/libvirt/images
+}
+
+pkg_preinst() {
+	# we only ever want to generate this once
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
+	fi
+
+	# We really don't want to use or support old PolicyKit cause it
+	# screws with the new polkit integration
+	if has_version sys-auth/policykit; then
+		rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
+	fi
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize libvirt.py
+
+	elog
+	if use policykit && has_version sys-auth/policykit; then
+		elog "You must have run the following at least once:"
+		elog
+		elog "$ polkit-auth --grant org.libvirt.unix.manage --user \"USERNAME\""
+		elog
+		elog "to grant USERNAME access to libvirt when using USE=policykit"
+	else
+		elog "To allow normal users to connect to libvirtd you must change the"
+		elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	elog
+	elog "For the basic networking support (bridged and routed networks)"
+	elog "you don't need any extra software. For more complex network modes"
+	elog "including but not limited to NATed network, you can enable the"
+	elog "'virt-network' USE flag."
+	elog
+	if has_version net-dns/dnsmasq; then
+		ewarn "If you have a DNS server setup on your machine, you will have"
+		ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
+		ewarn " bind-interfaces"
+		ewarn " interface or except-interface"
+		ewarn
+		ewarn "Otherwise you might have issues with your existing DNS server."
+	fi
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup libvirt.py
+}
-- 
2.26.2