From d0bf18ac90ee0cc0eccca63b96a0590a79a04a5d Mon Sep 17 00:00:00 2001
From: "Marty E. Plummer" <hanetzer@startmail.com>
Date: Sat, 7 Jul 2018 19:30:43 -0500
Subject: [PATCH] dev-libs/libevdev: add live ebuild

Package-Manager: Portage-2.3.41, Repoman-2.3.9
---
 dev-libs/libevdev/libevdev-9999.ebuild | 48 ++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-libs/libevdev/libevdev-9999.ebuild

diff --git a/dev-libs/libevdev/libevdev-9999.ebuild b/dev-libs/libevdev/libevdev-9999.ebuild
new file mode 100644
index 000000000000..d551ca6aecf2
--- /dev/null
+++ b/dev-libs/libevdev/libevdev-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit multilib-minimal python-any-r1
+
+DESCRIPTION="Handler library for evdev events"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libevdev/"
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libevdev.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://www.freedesktop.org/software/libevdev/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc static-libs"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+RESTRICT="test" # Tests need to run as root.
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+	if use doc ;then
+		local HTML_DOCS=( doc/html/. )
+		einstalldocs
+	fi
+}
-- 
2.26.2