From ca96ad2e887d64febee4984ace90b04daa805979 Mon Sep 17 00:00:00 2001
From: Sven Wegener <swegener@gentoo.org>
Date: Mon, 26 Nov 2018 16:39:31 +0000
Subject: [PATCH] net-dns/pdns-recursor: Version bump, security bug #671982

Bug: https://bugs.gentoo.org/671982
Signed-off-by: Sven Wegener <swegener@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
---
 net-dns/pdns-recursor/Manifest                |  1 +
 .../pdns-recursor/pdns-recursor-4.1.8.ebuild  | 78 +++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 net-dns/pdns-recursor/pdns-recursor-4.1.8.ebuild

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 33509d307963..a6f7174342d6 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1 +1,2 @@
 DIST pdns-recursor-4.1.7.tar.bz2 1237866 BLAKE2B f87263c0b4c40c8d5822edd75b338fc23609fb648c71b0665fc3cfd6b1d54679884dcdcc196580ab663f4fdeafaa72bee41308e3720b50374f2dfeb425259b6f SHA512 eb119b0da034624a95aadd4800e376b80f69b7151e773437c0f644bdc5a38a377c5547bcd57606367e148eaddf0b7de8f5f5ff3ab582b50ceb190f2fada5980a
+DIST pdns-recursor-4.1.8.tar.bz2 1237750 BLAKE2B 1170198ea2ed9f1d16f7d8fa76e4c9f8bc56e3c72a391d094e7380d84657b55daa6f45acf4737a9d9b144f2deae64103c40dc3b95550a853ee6f41f0f8a92c78 SHA512 5c09b8ce3f2f3ed6bb350cbd20e6cad4b66f9db85677605d57eca67187c05ddde5071af246a7398e2821c9ed2e5ff101d2b4928366b3ddf12013020fa9b74e61
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.1.8.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.1.8.ebuild
new file mode 100644
index 000000000000..2d88183b4f62
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.1.8.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="libressl luajit protobuf snmp sodium systemd"
+
+DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
+	luajit? ( dev-lang/luajit:= )
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	libressl? ( dev-libs/libressl:= )
+	!libressl? ( dev-libs/openssl:= )
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		$(use_enable systemd) \
+		$(use_enable sodium libsodium) \
+		$(use_with !luajit lua) \
+		$(use_with luajit luajit) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=nobody/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r1 pdns-recursor
+
+	keepdir /var/lib/powerdns
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}
-- 
2.26.2