From ca71b9d1ba90ab82b1200c15200536710ba056bc Mon Sep 17 00:00:00 2001
From: Jan Breuer <jan.breuer@jaybee.cz>
Date: Tue, 12 Jul 2016 20:07:12 +0200
Subject: [PATCH] =?utf8?q?net-misc/ptpd:=20fix=20bug=20#587328=20dep/snmp.?=
 =?utf8?q?c:224:9:=20error:=20unknown=20type=20name=20=E2=80=98U64?=
 =?utf8?q?=E2=80=99?=
MIME-Version: 1.0
Content-Type: text/plain; charset=utf8
Content-Transfer-Encoding: 8bit

Closes: https://github.com/gentoo/gentoo/pull/1878

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
---
 net-misc/ptpd/ptpd-2.3.1-r1.ebuild | 60 ++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-misc/ptpd/ptpd-2.3.1-r1.ebuild

diff --git a/net-misc/ptpd/ptpd-2.3.1-r1.ebuild b/net-misc/ptpd/ptpd-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..aa050b168509
--- /dev/null
+++ b/net-misc/ptpd/ptpd-2.3.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic systemd
+
+DESCRIPTION="Precision Time Protocol daemon"
+HOMEPAGE="https://github.com/ptpd/ptpd"
+
+SRC_URI="https://github.com/ptpd/ptpd/archive/${P}.tar.gz"
+KEYWORDS="~amd64 ~arm ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="debug experimental ntp +pcap snmp slave-only +statistics"
+RDEPEND="
+	pcap? ( net-libs/libpcap )
+	snmp? ( net-analyzer/net-snmp )"
+DEPEND="${RDEPEND}"
+RDEPEND="${RDEPEND}
+	ntp? ( net-misc/ntp )"
+
+S=${WORKDIR}/ptpd-${P}
+
+src_prepare() {
+	eapply_user
+	sed -i -e 's/U64/struct counter64/' src/dep/snmp.c || die "sed failed"
+	eautoreconf
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	econf \
+		--enable-daemon \
+		$(use_enable snmp) \
+		$(use_enable experimental experimental-options) \
+		$(use_enable statistics) \
+		$(use_enable debug runtime-debug) \
+		$(use_enable pcap) \
+		$(use_enable slave-only)
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+
+	insinto /etc
+	newins "src/ptpd2.conf.minimal" ptpd2.conf
+
+	newinitd "${FILESDIR}/ptpd2.rc" ptpd2
+	newconfd "${FILESDIR}/ptpd2.confd" ptpd2
+
+	systemd_dounit "${FILESDIR}/ptpd2.service"
+}
+
+pkg_postinst() {
+	elog "Do not forget to setup correct network interface."
+	elog "Change the config file /etc/ptpd2.conf to suit your needs."
+}
-- 
2.26.2