From c62ff4e60d02a91e341099f82c75977dba84aae2 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Thu, 23 Jan 2020 11:24:49 +0100
Subject: [PATCH] x11-misc/dunst: Add live ebuild

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 x11-misc/dunst/dunst-9999.ebuild | 53 ++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 x11-misc/dunst/dunst-9999.ebuild

diff --git a/x11-misc/dunst/dunst-9999.ebuild b/x11-misc/dunst/dunst-9999.ebuild
new file mode 100644
index 000000000000..e756b3ec1f81
--- /dev/null
+++ b/x11-misc/dunst/dunst-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 toolchain-funcs
+
+DESCRIPTION="Customizable and lightweight notification-daemon"
+HOMEPAGE="https://dunst-project.org/ https://github.com/dunst-project/dunst"
+EGIT_REPO_URI="https://github.com/${PN}-project/${PN}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS=""
+IUSE="dunstify"
+
+CDEPEND="
+	dev-libs/glib:2
+	sys-apps/dbus
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/pango[X]
+	dunstify? ( x11-libs/libnotify )
+"
+DEPEND="
+	${CDEPEND}
+	dev-lang/perl
+	virtual/pkgconfig
+"
+RDEPEND="${CDEPEND}"
+
+src_prepare() {
+	sed -i -e "/^CFLAGS/ { s:-g::;s:-O.:: }" config.mk || die
+
+	default
+}
+
+src_compile() {
+	tc-export CC
+	emake
+	use dunstify && emake dunstify
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+
+	use dunstify && dobin dunstify
+
+	dodoc AUTHORS CHANGELOG.md README.md RELEASE_NOTES
+}
-- 
2.26.2