From b649131c485a19a278e06429875c727025dedd75 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Thu, 6 Jul 2017 11:38:57 +0200
Subject: [PATCH] sys-libs/libblockdev: Initial commit.

Package-Manager: Portage-2.3.6, Repoman-2.3.2
---
 sys-libs/libblockdev/Manifest                |  1 +
 sys-libs/libblockdev/libblockdev-2.10.ebuild | 82 ++++++++++++++++++++
 sys-libs/libblockdev/metadata.xml            | 17 ++++
 3 files changed, 100 insertions(+)
 create mode 100644 sys-libs/libblockdev/Manifest
 create mode 100644 sys-libs/libblockdev/libblockdev-2.10.ebuild
 create mode 100644 sys-libs/libblockdev/metadata.xml

diff --git a/sys-libs/libblockdev/Manifest b/sys-libs/libblockdev/Manifest
new file mode 100644
index 000000000000..bc1902c2c2f3
--- /dev/null
+++ b/sys-libs/libblockdev/Manifest
@@ -0,0 +1 @@
+DIST libblockdev-2.10-1.tar.gz 247964 SHA256 67de96cb26e7d2e127e1e43bdf8e3456fc3b4b53fc62c6000d31d3b055775ecf SHA512 f808fd327b0e250cfb97a06ea716b5eb5c6812301b7da1cd6b757b3af44ceca038fe549f607b71fa395cfb1da6c70c20c8a224953fbc30ebe36c3d0e897eb15b WHIRLPOOL a8dc24fd5b9dfc53c45c1024733bb98fed7b3f103b85457f6ca479cda4d55f94b38fd660900b18ee748baab0c1dbf594caf10ef3cc7de21bfa4873ea7ebec39f
diff --git a/sys-libs/libblockdev/libblockdev-2.10.ebuild b/sys-libs/libblockdev/libblockdev-2.10.ebuild
new file mode 100644
index 000000000000..a829bbce0cf5
--- /dev/null
+++ b/sys-libs/libblockdev/libblockdev-2.10.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+inherit autotools python-single-r1
+
+MY_PV="${PV}-1"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A library for manipulating block devices"
+HOMEPAGE="https://github.com/rhinstaller/libblockdev"
+SRC_URI="https://github.com/rhinstaller/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bcache crypt dmraid doc lvm kbd python test"
+
+CDEPEND="
+	>=dev-libs/glib-2.42.2
+	dev-libs/libbytesize
+	>=sys-apps/util-linux-2.27
+	>=sys-block/parted-3.1
+	crypt? (
+		>=dev-libs/nss-3.18.0
+		dev-libs/volume_key
+		>=sys-fs/cryptsetup-1.6.7
+	)
+	dmraid? (
+		sys-fs/dmraid
+		sys-fs/lvm2
+	)
+	lvm? (
+		sys-fs/lvm2
+		virtual/udev
+	)
+	kbd? ( >=sys-apps/kmod-19 )
+	python? ( ${PYTHON_DEPS} )
+"
+
+DEPEND="
+	${CDEPEND}
+	>=dev-libs/gobject-introspection-1.3.0
+	doc? ( dev-util/gtk-doc )
+"
+
+RDEPEND="
+	${CDEPEND}
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-btrfs
+		--with-fs
+		--with-part
+		--without-mpath
+		$(use_enable test tests)
+		$(use_with bcache)
+		$(use_with crypt crypto)
+		$(use_with dmraid dm)
+		$(use_with doc gtk-doc)
+		$(use_with lvm lvm)
+		$(use_with lvm lvm-dbus)
+		$(use_with kbd)
+		$(use_with python python3)
+	)
+	econf "${myeconfargs[@]}"
+}
diff --git a/sys-libs/libblockdev/metadata.xml b/sys-libs/libblockdev/metadata.xml
new file mode 100644
index 000000000000..6f4957ace55d
--- /dev/null
+++ b/sys-libs/libblockdev/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>polynomial-c@gentoo.org</email>
+    <name>Lars Wendler</name>
+  </maintainer>
+  <use>
+    <flag name="bcache">Enable block device cache support.</flag>
+    <flag name="dmraid">Support for dmraid devices, also known as ATA-RAID, or Fake RAID.</flag>
+    <flag name="lvm">Enable support for Logical Volume Management via <pkg>sys-fs/lvm2</pkg>.</flag>
+    <flag name="kbd">Enable kernel block device support.</flag>
+  </use>
+  <upstream>
+    <remote-id type="github">storaged-project/libblockdev</remote-id>
+  </upstream>
+</pkgmetadata>
-- 
2.26.2