From b470a79e58cb2b630812ab8635dc7864d14b7b1a Mon Sep 17 00:00:00 2001
From: Craig Andrews <candrews@gentoo.org>
Date: Tue, 19 Mar 2019 14:39:34 -0400
Subject: [PATCH] sys-block/zram-init: -9999 live version

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>
---
 sys-block/zram-init/zram-init-9999.ebuild | 54 +++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 sys-block/zram-init/zram-init-9999.ebuild

diff --git a/sys-block/zram-init/zram-init-9999.ebuild b/sys-block/zram-init/zram-init-9999.ebuild
new file mode 100644
index 000000000000..2b9aa4db74d0
--- /dev/null
+++ b/sys-block/zram-init/zram-init-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit readme.gentoo-r1 systemd
+
+DESCRIPTION="Scripts to support compressed swap devices or ramdisks with zram"
+HOMEPAGE="https://github.com/vaeth/zram-init/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/vaeth/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/vaeth/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+RDEPEND=">=app-shells/push-2.0
+	!<sys-apps/openrc-0.13"
+
+DISABLE_AUTOFORMATTING="true"
+DOC_CONTENTS="To use zram, activate it in your kernel and add it to default runlevel:
+	rc-config add zram default
+If you use systemd enable zram_swap, tmp, and/or var_tmp with systemctl.
+You might need to modify /etc/modprobe.d/zram.conf"
+
+src_prepare() {
+	use prefix || sed -i \
+		-e '1s"^#!/usr/bin/env sh$"#!'"${EPREFIX}/bin/sh"'"' \
+		-- sbin/* || die
+	default
+}
+
+src_install() {
+	doinitd openrc/init.d/*
+	doconfd openrc/conf.d/*
+	systemd_dounit systemd/system/*
+	insinto /etc/modprobe.d
+	doins modprobe.d/*
+	insinto /usr/share/zsh/site-functions
+	doins zsh/*
+	dodoc AUTHORS ChangeLog README.md
+	readme.gentoo_create_doc
+	into /
+	dosbin sbin/*
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
-- 
2.26.2