From b17da05247d1bfb94f4be3fd9fea628de7532286 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Tue, 23 Apr 2019 11:13:07 +0200
Subject: [PATCH] dev-vcs/tortoisehg: Bump to version 4.9.1

Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-vcs/tortoisehg/Manifest                |  1 +
 dev-vcs/tortoisehg/tortoisehg-4.9.1.ebuild | 79 ++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 dev-vcs/tortoisehg/tortoisehg-4.9.1.ebuild

diff --git a/dev-vcs/tortoisehg/Manifest b/dev-vcs/tortoisehg/Manifest
index b15f2e1fa4cd..bd6b152fbe93 100644
--- a/dev-vcs/tortoisehg/Manifest
+++ b/dev-vcs/tortoisehg/Manifest
@@ -1 +1,2 @@
+DIST tortoisehg-4.9.1.tar.gz 7960667 BLAKE2B f8a6ed65967c6389b65fd9388b3e898bf4ce09e7f95dd88467a10c061b9454eab76d0308905fd417575bf6d75dd7129a2f303bc774fd8e68824b33c18fd8054c SHA512 aef1b0d6047114794bfe78de2c0def83748e238917ce44fb56d562d53c26666dbb385867da70c4625893b148e2affa3766e40292348b78aff428df5a77d8f902
 DIST tortoisehg-4.9.tar.gz 7960163 BLAKE2B bc13032ba1e36ed3e6aca978cb3917b2e5fdcf1b7dab2e66a34a0aca2e084960954f9ec135a1c2120e09931b876db7d1f3d0f3a8f69f950ff939eea9d7814523 SHA512 cc7b0360c6b362b0b9695a484b59eea879e1d4e28ed68e98ce6975342a22ddafc97976c5b0cdea289bfd78932dacf76c0b236e36bec48acd48ee361f2c09ff13
diff --git a/dev-vcs/tortoisehg/tortoisehg-4.9.1.ebuild b/dev-vcs/tortoisehg/tortoisehg-4.9.1.ebuild
new file mode 100644
index 000000000000..ff2d174552da
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-4.9.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+
+inherit desktop distutils-r1
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-4.8 <dev-vcs/mercurial-4.10"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+	EHG_REVISION="stable"
+	HG_DEPEND="dev-vcs/mercurial"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.9.4:=[qt5(+),${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-1.0.3 )"
+
+# Workaround race condition in build_qt
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	if [[ ${L10N+set} ]]; then
+		cd i18n/tortoisehg || die
+		local x y keep
+		for x in *.po; do
+			keep=false
+			for y in ${L10N}; do
+				if [[ ${y} == ${x%.po}* ]]; then
+					keep=true
+					break
+				fi
+			done
+			${keep} || rm "${x}" || die
+		done
+		cd "${S}" || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	if use doc ; then
+		dohtml -r doc/build/html/
+	fi
+	newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+	domenu contrib/thg.desktop
+
+	# Remove file that collides with >=mercurial-4.0 (bug #599266).
+	rm "${ED}"/usr/$(get_libdir)/${EPYTHON}/site-packages/hgext3rd/__init__.py* \
+		|| die
+}
+
+pkg_postinst() {
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+	elog "dev-python/qscintilla-python."
+}
-- 
2.26.2