From a28313adbdf5e0b12f692bb713f7b58e875d6b24 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Fri, 10 Mar 2017 12:35:50 +0100
Subject: [PATCH] dev-python/cangjie: Port to EAPI 6

* Add py3.5 and 3.6 support

Package-Manager: Portage-2.3.4, Repoman-2.3.2
---
 dev-python/cangjie/cangjie-1.2-r1.ebuild | 56 ++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/cangjie/cangjie-1.2-r1.ebuild

diff --git a/dev-python/cangjie/cangjie-1.2-r1.ebuild b/dev-python/cangjie/cangjie-1.2-r1.ebuild
new file mode 100644
index 000000000000..d3daf09ed18c
--- /dev/null
+++ b/dev-python/cangjie/cangjie-1.2-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit autotools python-r1
+
+DESCRIPTION="The Python bindings to libcangjie"
+HOMEPAGE="http://cangjians.github.io"
+SRC_URI="https://github.com/Cangjians/pycangjie/releases/download/v${PV}/cangjie-${PV}.tar.xz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	app-i18n/libcangjie
+	${PYTHON_DEPS}"
+DEPEND="
+	${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/${P}-cython-022.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	myeconf() {
+		ECONF_SOURCE="${S}" econf PYTHON="${PYTHON}"
+	}
+	python_foreach_impl run_in_build_dir myeconf
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	einstalldocs
+
+	# package only installs python modules
+	find "${D}" -name '*.la' -delete || die
+}
-- 
2.26.2