From 9f0f3455a481afb5ca69cb13d9a2eaebaff259a7 Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Sun, 8 Nov 2015 17:20:25 +0100
Subject: [PATCH] www-client/httrack: Handle FEATURES=nodoc (bug #493376)

Also bump to EAPI 5 and address "matches more than one slot" warning

Package-Manager: portage-2.2.24
---
 www-client/httrack/httrack-3.48.21-r1.ebuild | 48 ++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 www-client/httrack/httrack-3.48.21-r1.ebuild

diff --git a/www-client/httrack/httrack-3.48.21-r1.ebuild b/www-client/httrack/httrack-3.48.21-r1.ebuild
new file mode 100644
index 000000000000..bf948268db9f
--- /dev/null
+++ b/www-client/httrack/httrack-3.48.21-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils
+
+DESCRIPTION="HTTrack Website Copier, Open Source Offline Browser"
+HOMEPAGE="http://www.httrack.com/"
+SRC_URI="http://mirror.httrack.com/historical/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.5.1-r1
+	dev-libs/openssl:="
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS README greetings.txt history.txt )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.48.13-minizip.patch
+}
+
+src_configure() {
+	econf $(use_enable static-libs static) \
+		--docdir=/usr/share/doc/${PF} \
+		--htmldir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	# Make webhttrack work despite FEATURES=nodoc cutting
+	# all of /usr/share/doc/ away (bug #493376)
+	if has nodoc ${FEATURES} ; then
+		dodir /usr/share/${PF}/
+		mv "${D}"/usr/share/{doc/,}${PF}/html || die
+
+		rm "${D}"/usr/share/httrack/html || die
+		dosym /usr/share/${PF}/html /usr/share/httrack/html
+	fi
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
2.26.2