From 9c4f60ca18d922a07f8fc87fb47b4ba66d848f59 Mon Sep 17 00:00:00 2001
From: Dennis Lamm <expeditioneer@gentoo.org>
Date: Wed, 8 Mar 2017 20:21:33 +0100
Subject: [PATCH] net-libs/gssdp version bump to 1.0.1

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---
 net-libs/gssdp/Manifest           |  1 +
 net-libs/gssdp/gssdp-1.0.1.ebuild | 57 +++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 net-libs/gssdp/gssdp-1.0.1.ebuild

diff --git a/net-libs/gssdp/Manifest b/net-libs/gssdp/Manifest
index dc1ba36d881b..2560cc8dacb8 100644
--- a/net-libs/gssdp/Manifest
+++ b/net-libs/gssdp/Manifest
@@ -1 +1,2 @@
 DIST gssdp-0.14.16.tar.xz 301000 SHA256 54520bfb230b9c8c938eba88d87df44e04749682c95fb8aa381d13441345c5b2 SHA512 1ff3a8bcb8af537bdb26d56edd3452fba9a781264bd29debd08ad901f47b060f3a80006b63c52fe93d487200bad8d5d0745937de868ad78167464dc0cf2fa3de WHIRLPOOL 3fdf6d1c1aca1b7c3295cb390656ba8fcacb9ec1655aaccaa07c246605d994ca932cd3391ea08979ade1d9bf2ffea3eb8c37930fb162e763673dd0f1904d10e0
+DIST gssdp-1.0.1.tar.xz 312336 SHA256 601d67f40bc28c067742b7c46f3018da96b364fd3e83f30ddac6e190e323d2e1 SHA512 e823cb62d440f1ddab3ec5012718a9808ac736077b09c2a7cbce38a876de613c4960c986b7486fa0eed79651ace9865ca5418c195a8682ba621378465ec60247 WHIRLPOOL 32a602881a9634f580f110869305eb75a462fb3cfe5ac8e5f1c416e61a3e3def5afd5a7ca5e148c958f2a88f7b3651a39af4173dd8d24ac412e7792e3c01ee24
diff --git a/net-libs/gssdp/gssdp-1.0.1.ebuild b/net-libs/gssdp/gssdp-1.0.1.ebuild
new file mode 100644
index 000000000000..e72a8080cc12
--- /dev/null
+++ b/net-libs/gssdp/gssdp-1.0.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 multilib-minimal vala
+
+DESCRIPTION="A GObject-based API for handling resource discovery and announcement over SSDP"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="+introspection gtk"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=net-libs/libsoup-2.44.2:2.4[${MULTILIB_USEDEP},introspection?]
+	gtk? ( >=x11-libs/gtk+-3.0:3 )
+	introspection? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.36:= )
+	!<net-libs/gupnp-vala-0.10.3
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.14
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	# Disable functional test as it requires port that might be used by rygel to
+	# be free of use
+	sed 's/\(check_PROGRAMS.*\)test-functional$(EXEEXT)/\1/' \
+		-i "${S}"/tests/Makefile.in || die
+
+	use introspection && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(multilib_native_use_with gtk) \
+		--disable-static
+
+	if multilib_is_native_abi; then
+		# fix gtk-doc
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
-- 
2.26.2