From 7f742047def6998c4b3fb7c4cd243ca415955800 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Thu, 21 Dec 2017 03:11:40 -0600
Subject: [PATCH] dev-libs/serd: 0.28.0-r1 for multilib

Package-Manager: Portage-2.3.14, Repoman-2.3.6
---
 dev-libs/serd/serd-0.28.0-r1.ebuild | 52 +++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-libs/serd/serd-0.28.0-r1.ebuild

diff --git a/dev-libs/serd/serd-0.28.0-r1.ebuild b/dev-libs/serd/serd-0.28.0-r1.ebuild
new file mode 100644
index 000000000000..1640a0cbfe09
--- /dev/null
+++ b/dev-libs/serd/serd-0.28.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE='threads(+)'
+inherit python-any-r1 waf-utils multilib-build multilib-minimal
+
+DESCRIPTION="Library for RDF syntax which supports reading and writing Turtle and NTriples"
+HOMEPAGE="http://drobilla.net/software/serd/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc static-libs test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )"
+
+DOCS=( "AUTHORS" "NEWS" "README.md" )
+
+src_prepare() {
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir=/usr/share/doc/${PF} \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+	default
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+	default
+}
-- 
2.26.2