From 7e17670a886d15ab6a0ba40c906cbbe0dce5d066 Mon Sep 17 00:00:00 2001
From: Alexey Sokolov <sokolov@google.com>
Date: Sun, 1 Apr 2018 11:54:14 +0100
Subject: [PATCH] app-i18n/fbterm: fix file collision with sys-libs/ncurses-6.1

Bug: https://bugs.gentoo.org/648472
Closes: https://github.com/gentoo/gentoo/pull/7764
Package-Manager: Portage-2.3.24, Repoman-2.3.6
---
 ...erm-1.7-r3.ebuild => fbterm-1.7-r4.ebuild} |  8 ++-
 app-i18n/fbterm/fbterm-1.7-r5.ebuild          | 59 +++++++++++++++++++
 app-i18n/fbterm/files/fbterm-noterminfo.patch | 15 +++++
 3 files changed, 79 insertions(+), 3 deletions(-)
 rename app-i18n/fbterm/{fbterm-1.7-r3.ebuild => fbterm-1.7-r4.ebuild} (88%)
 create mode 100644 app-i18n/fbterm/fbterm-1.7-r5.ebuild
 create mode 100644 app-i18n/fbterm/files/fbterm-noterminfo.patch

diff --git a/app-i18n/fbterm/fbterm-1.7-r3.ebuild b/app-i18n/fbterm/fbterm-1.7-r4.ebuild
similarity index 88%
rename from app-i18n/fbterm/fbterm-1.7-r3.ebuild
rename to app-i18n/fbterm/fbterm-1.7-r4.ebuild
index 2138ece5ef1e..8b906331dde7 100644
--- a/app-i18n/fbterm/fbterm-1.7-r3.ebuild
+++ b/app-i18n/fbterm/fbterm-1.7-r4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="6"
@@ -14,11 +14,13 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 IUSE="gpm video_cards_vesa"
 
-RDEPEND="media-libs/fontconfig
+COMMON_DEPEND="media-libs/fontconfig
 	media-libs/freetype:2
 	gpm? ( sys-libs/gpm )
 	video_cards_vesa? ( dev-libs/libx86 )"
-DEPEND="${RDEPEND}
+RDEPEND="${COMMON_DEPEND}
+	!>=sys-libs/ncurses-6.1"
+DEPEND="${COMMON_DEPEND}
 	sys-libs/ncurses
 	virtual/pkgconfig"
 
diff --git a/app-i18n/fbterm/fbterm-1.7-r5.ebuild b/app-i18n/fbterm/fbterm-1.7-r5.ebuild
new file mode 100644
index 000000000000..a4b174a1f859
--- /dev/null
+++ b/app-i18n/fbterm/fbterm-1.7-r5.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools fcaps
+
+DESCRIPTION="Fast terminal emulator for the Linux framebuffer"
+HOMEPAGE="https://code.google.com/p/fbterm"
+SRC_URI="https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/${PN}/${P}.0.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gpm video_cards_vesa"
+
+RDEPEND="media-libs/fontconfig
+	media-libs/freetype:2
+	gpm? ( sys-libs/gpm )
+	video_cards_vesa? ( dev-libs/libx86 )
+	>=sys-libs/ncurses-6.1"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gcc6.patch
+	"${FILESDIR}"/${PN}-noterminfo.patch
+)
+
+FILECAPS=(
+	cap_sys_tty_config+ep usr/bin/${PN}
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable gpm) \
+		$(use_enable video_cards_vesa vesa)
+}
+
+src_install() {
+	default
+
+	use filecaps || fperms u+s /usr/bin/${PN}
+}
+
+pkg_postinst() {
+	fcaps_pkg_postinst
+
+	elog "${PN} won't work with vga16fb. You have to use other native"
+	elog "framebuffer drivers or vesa driver."
+	elog "See ${EPREFIX}/usr/share/doc/${P}/README for details."
+	elog
+	elog "To use ${PN}, ensure you are in video group."
+}
diff --git a/app-i18n/fbterm/files/fbterm-noterminfo.patch b/app-i18n/fbterm/files/fbterm-noterminfo.patch
new file mode 100644
index 000000000000..76cf9fc77925
--- /dev/null
+++ b/app-i18n/fbterm/files/fbterm-noterminfo.patch
@@ -0,0 +1,15 @@
+commit 77c90022233634a3c891dc778585c526d9d846a1
+Author: Alexey Sokolov <sokolov@google.com>
+Date:   Sun Apr 1 11:33:20 2018 +0100
+
+    Don't install terminfo: ncurses-6.1 supports fbterm itself
+
+    https://bugs.gentoo.org/648472
+
+diff --git a/Makefile.am b/Makefile.am
+index 10814b6..8adcd57 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -1 +1 @@
+-SUBDIRS = src im terminfo doc
++SUBDIRS = src im doc
-- 
2.26.2