From 7b9e497628a324e7b2291cf0dd79a73b4dd66757 Mon Sep 17 00:00:00 2001
From: David Roman <davidroman96@gmail.com>
Date: Mon, 27 Nov 2017 21:52:53 +0100
Subject: [PATCH] dev-util/radare2: add bash-completion support

Closes: https://github.com/gentoo/gentoo/pull/6327
---
 dev-util/radare2/radare2-2.1.0-r1.ebuild | 60 ++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-util/radare2/radare2-2.1.0-r1.ebuild

diff --git a/dev-util/radare2/radare2-2.1.0-r1.ebuild b/dev-util/radare2/radare2-2.1.0-r1.ebuild
new file mode 100644
index 000000000000..f69a9666f3b3
--- /dev/null
+++ b/dev-util/radare2/radare2-2.1.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils bash-completion-r1
+
+DESCRIPTION="unix-like reverse engineering framework and commandline tools"
+HOMEPAGE="http://www.radare.org"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/radare/radare2"
+else
+	SRC_URI="https://github.com/radare/radare2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+fi
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.9-nogit.patch
+)
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ssl +system-capstone zsh-completion bash-completion"
+
+RDEPEND="
+	ssl? ( dev-libs/openssl:0= )
+	system-capstone? ( dev-libs/capstone:0= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_configure() {
+	econf \
+		$(use_with ssl openssl) \
+		$(use_with system-capstone syscapstone)
+}
+
+src_install() {
+	default
+
+	if use zsh-completion; then
+		insinto /usr/share/zsh/site-functions
+		doins doc/zsh/_*
+	fi
+
+	if use bash-completion; then
+		newbashcomp doc/bash_autocompletion.sh "${PN}"
+	fi
+
+	# a workaround for unstable $(INSTALL) call, bug #574866
+	local d
+	for d in doc/*; do
+		if [[ -d $d ]]; then
+			rm -rfv "$d" || die "failed to delete '$d'"
+		fi
+	done
+}
-- 
2.26.2