From 5d834d6d463f4d043439824ca97bb45d98e50433 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Tue, 1 May 2018 19:55:43 +0200
Subject: [PATCH] games-rpg/zsdx: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9
---
 games-rpg/zsdx/zsdx-1.9.0-r1.ebuild | 53 +++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 games-rpg/zsdx/zsdx-1.9.0-r1.ebuild

diff --git a/games-rpg/zsdx/zsdx-1.9.0-r1.ebuild b/games-rpg/zsdx/zsdx-1.9.0-r1.ebuild
new file mode 100644
index 000000000000..dc00fda49542
--- /dev/null
+++ b/games-rpg/zsdx/zsdx-1.9.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils gnome2-utils
+
+DESCRIPTION="A free 2D Zelda fangame"
+HOMEPAGE="http://www.solarus-games.org/"
+SRC_URI="http://www.zelda-solarus.com/downloads/${PN}/${P}.tar.gz"
+
+LICENSE="all-rights-reserved CC-BY-SA-3.0 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="mirror"
+
+RDEPEND="
+	>=games-engines/solarus-1.3.0
+	<games-engines/solarus-1.4.0
+"
+DEPEND="app-arch/zip"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSOLARUS_INSTALL_DATAROOTDIR="/usr/share"
+		-DSOLARUS_INSTALL_BINDIR="/usr/bin"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newicon -s 48 build/icons/${PN}_icon_48.png ${PN}.png
+	newicon -s 256 build/icons/${PN}_icon_256.png ${PN}.png
+
+	# install proper wrapper script
+	rm -f "${ED}"/usr/bin/${PN}
+	make_wrapper ${PN} "solarus \"/usr/share/solarus/${PN}\""
+
+	make_desktop_entry "${PN}" "Zelda: Mystery of Solarus DX"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
2.26.2