From 5932c0c0ee9894f8ccc71f595712231573351d66 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Sun, 19 Feb 2017 15:05:07 +0100
Subject: [PATCH] dev-ruby/slim: loosen dependency on temple

Package-Manager: portage-2.3.3
---
 dev-ruby/slim/slim-3.0.7-r1.ebuild | 51 ++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-ruby/slim/slim-3.0.7-r1.ebuild

diff --git a/dev-ruby/slim/slim-3.0.7-r1.ebuild b/dev-ruby/slim/slim-3.0.7-r1.ebuild
new file mode 100644
index 000000000000..a2770dc8e055
--- /dev/null
+++ b/dev-ruby/slim/slim-3.0.7-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGES README.md"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_TASK_DOC="yard"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A template language aiming to reduce the syntax to the essential parts"
+HOMEPAGE="http://slim-lang.com/"
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~arm ~ppc"
+SLOT="0"
+IUSE="doc"
+
+ruby_add_rdepend ">=dev-ruby/tilt-1.3.3:* <dev-ruby/tilt-2.1:*
+	>=dev-ruby/temple-0.7.6:0.7"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard dev-ruby/redcarpet )"
+
+ruby_add_bdepend "test? ( dev-ruby/sass )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# This sinatra code expects tests to be installed but we strip those.
+	sed -i -e "s/require 'sinatra'/require 'bogussinatra'/" Rakefile || die
+
+	# Avoid tests for things we don't have. The builder test does not pass with tilt 2.x
+	sed -i -e '/test_wip_render_with_asciidoc/,/^  end/ s:^:#:' \
+		-e '/test_render_with_wiki/,/^  end/ s:^:#:' \
+		-e '/test_render_with_creole/,/^  end/ s:^:#:' \
+		-e '/test_render_with_builder/,/^  end/ s:^:#:' \
+		-e '/test_render_with_org/,/^  end/ s:^:#:' test/core/test_embedded_engines.rb || die
+
+	# Relax temple version check (already fixed upstream)
+	sed -i -e 's/0.7.6/0.7/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_prepare() {
+	sed -i -e '/Open3/ s:ruby:'${RUBY}':' test/core/test_commands.rb || die
+}
-- 
2.26.2