From 4b3b7f011e8b0a3134ceba9aab106df40aea836b Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 21 Nov 2017 23:22:21 +0100
Subject: [PATCH] app-portage/gemato: New ebuild for Gentoo Manifest Tool

---
 app-portage/gemato/gemato-9999.ebuild | 31 +++++++++++++++++++++++++++
 app-portage/gemato/metadata.xml       | 18 ++++++++++++++++
 2 files changed, 49 insertions(+)
 create mode 100644 app-portage/gemato/gemato-9999.ebuild
 create mode 100644 app-portage/gemato/metadata.xml

diff --git a/app-portage/gemato/gemato-9999.ebuild b/app-portage/gemato/gemato-9999.ebuild
new file mode 100644
index 000000000000..2df8e801b285
--- /dev/null
+++ b/app-portage/gemato/gemato-9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# backports.lzma is broken with pypy
+# pyblake2 & pysha3 are broken with pypy3
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Stand-alone Manifest generation & verification tool"
+HOMEPAGE="https://github.com/mgorny/gemato"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/mgorny/gemato.git"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="+blake2 bzip2 +gpg lzma sha3"
+
+RDEPEND="
+	blake2? ( $(python_gen_cond_dep 'dev-python/pyblake2[${PYTHON_USEDEP}]' python{2_7,3_4,3_5} pypy{,3}) )
+	bzip2? ( $(python_gen_cond_dep 'dev-python/bz2file[${PYTHON_USEDEP}]' python2_7 pypy) )
+	gpg? ( app-crypt/gnupg )
+	lzma? ( $(python_gen_cond_dep 'dev-python/backports-lzma[${PYTHON_USEDEP}]' python2_7 pypy) )
+	sha3? ( $(python_gen_cond_dep 'dev-python/pysha3[${PYTHON_USEDEP}]' python{2_7,3_4,3_5} pypy{,3}) )"
+DEPEND="${RDEPEND}"
+
+python_test() {
+	"${PYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
diff --git a/app-portage/gemato/metadata.xml b/app-portage/gemato/metadata.xml
new file mode 100644
index 000000000000..805485e949c7
--- /dev/null
+++ b/app-portage/gemato/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>mgorny@gentoo.org</email>
+		<name>Michał Górny</name>
+	</maintainer>
+	<use>
+		<flag name='blake2'>Install dependencies needed for BLAKE2 hash
+			functions</flag>
+		<flag name='sha3'>Install dependencies needed for SHA3 hash
+			functions</flag>
+	</use>
+	<upstream>
+		<bugs-to>https://github.com/mgorny/gemato/issues/</bugs-to>
+		<remote-id type="github">mgorny/gemato</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
2.26.2