From 49f2b5caea378028462ab01090ad2241aa8cebe0 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 9 May 2017 16:23:21 +0200
Subject: [PATCH] dev-python/repoze-who: Fix namespace support

---
 .../repoze-who/repoze-who-2.2-r1.ebuild       | 47 +++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/repoze-who/repoze-who-2.2-r1.ebuild

diff --git a/dev-python/repoze-who/repoze-who-2.2-r1.ebuild b/dev-python/repoze-who/repoze-who-2.2-r1.ebuild
new file mode 100644
index 000000000000..f2f3ac568592
--- /dev/null
+++ b/dev-python/repoze-who/repoze-who-2.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="repoze.who is an identification and authentication framework for WSGI"
+HOMEPAGE="http://www.repoze.org"
+SRC_URI="mirror://pypi/${PN:0:1}/repoze.who/repoze.who-${PV}.tar.gz"
+S="${WORKDIR}/repoze.who-${PV}"
+
+LICENSE="repoze"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	dev-python/namespace-repoze[${PYTHON_USEDEP}]
+	dev-python/webob[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	esetup.py test
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# install __init__.py files for sub-namespaces
+	python_moduleinto repoze/who
+	python_domodule repoze/who/__init__.py
+
+	python_moduleinto repoze/who/plugins
+	python_domodule repoze/who/plugins/__init__.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name '*.pth' -delete || die
+}
-- 
2.26.2