From 442ebfd45c180c360a6cfb1a27d4ff941284c784 Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Sat, 29 Dec 2018 11:47:07 +0000
Subject: [PATCH] games-emulation/dosbox: opengl USE flag should require
 libsdl[opengl]

Closes: https://bugs.gentoo.org/608366
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 .../dosbox/dosbox-0.74_p20160629-r2.ebuild    | 70 +++++++++++++++++++
 games-emulation/dosbox/dosbox-9999.ebuild     |  4 +-
 2 files changed, 72 insertions(+), 2 deletions(-)
 create mode 100644 games-emulation/dosbox/dosbox-0.74_p20160629-r2.ebuild

diff --git a/games-emulation/dosbox/dosbox-0.74_p20160629-r2.ebuild b/games-emulation/dosbox/dosbox-0.74_p20160629-r2.ebuild
new file mode 100644
index 000000000000..d9dccc1aa6aa
--- /dev/null
+++ b/games-emulation/dosbox/dosbox-0.74_p20160629-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools desktop flag-o-matic
+
+PATCH=3989
+GLIDE_PATCH=3722fc563b737d2d7933df6a771651c2154e6f7b
+
+DESCRIPTION="DOS emulator"
+HOMEPAGE="http://dosbox.sourceforge.net/"
+SRC_URI="mirror://gentoo/dosbox-code-0-${PATCH}-dosbox-trunk.zip
+	glide? ( https://raw.githubusercontent.com/voyageur/openglide/${GLIDE_PATCH}/platform/dosbox/dosbox_glide.diff -> dosbox_glide-${GLIDE_PATCH}.diff )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="alsa debug glide hardened opengl"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	glide? ( media-libs/openglide )
+	opengl? ( virtual/glu virtual/opengl )
+	debug? ( sys-libs/ncurses:0 )
+	media-libs/libpng:0
+	media-libs/libsdl[joystick,opengl?,video,X]
+	media-libs/sdl-net
+	media-libs/sdl-sound"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${PN}-code-0-${PATCH}-dosbox-trunk
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.74-gcc46.patch
+)
+
+src_prepare() {
+	use glide && eapply "${DISTDIR}"/dosbox_glide-${GLIDE_PATCH}.diff
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use glide && append-cppflags -I"${EPREFIX}"/usr/include/openglide
+
+	econf \
+		$(use_enable alsa alsa-midi) \
+		$(use_enable !hardened dynamic-core) \
+		$(use_enable !hardened dynamic-x86) \
+		$(use_enable debug) \
+		$(use_enable opengl)
+}
+
+src_install() {
+	default
+	make_desktop_entry dosbox DOSBox /usr/share/pixmaps/dosbox.ico
+	doicon src/dosbox.ico
+}
+
+pkg_postinst() {
+	if use glide; then
+		elog "You have enabled unofficial Glide emulation. To use this, symlink"
+		elog "or copy ${EPREFIX}/usr/share/openglide/glide2x-dosbox.ovl to your game's"
+		elog "directory and add the following to your DOSBox configuration."
+		elog ""
+		elog "[glide]"
+		elog "glide=true"
+	fi
+}
diff --git a/games-emulation/dosbox/dosbox-9999.ebuild b/games-emulation/dosbox/dosbox-9999.ebuild
index 786b1f786887..a5bfff9c4f30 100644
--- a/games-emulation/dosbox/dosbox-9999.ebuild
+++ b/games-emulation/dosbox/dosbox-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -28,7 +28,7 @@ DEPEND="alsa? ( media-libs/alsa-lib )
 	opengl? ( virtual/glu virtual/opengl )
 	debug? ( sys-libs/ncurses:0 )
 	media-libs/libpng:0
-	media-libs/libsdl[joystick,video,X]
+	media-libs/libsdl[joystick,opengl?,video,X]
 	media-libs/sdl-net
 	media-libs/sdl-sound"
 RDEPEND=${DEPEND}
-- 
2.26.2