From 421a6ee1583bb50f2caaea4173d79055916675cf Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Sun, 17 Sep 2017 11:22:02 +0200
Subject: [PATCH] net-analyzer/nsat: Reintroduce sys-libs/glibc-2.26 (bug
 #371025) compat changes in a new ebuild instead of STRAIGHT TO STABLE.

Package-Manager: Portage-2.3.8, Repoman-2.3.3
---
 net-analyzer/nsat/nsat-1.5-r4.ebuild | 79 ++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 net-analyzer/nsat/nsat-1.5-r4.ebuild

diff --git a/net-analyzer/nsat/nsat-1.5-r4.ebuild b/net-analyzer/nsat/nsat-1.5-r4.ebuild
new file mode 100644
index 000000000000..52381d75fcfb
--- /dev/null
+++ b/net-analyzer/nsat/nsat-1.5-r4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Network Security Analysis Tool, an application-level network security scanner"
+HOMEPAGE="http://nsat.sourceforge.net/"
+SRC_URI="mirror://sourceforge/nsat/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="X"
+
+RDEPEND="
+	dev-libs/libmix
+	net-libs/libpcap
+	X? (
+		dev-lang/tk:*
+		x11-libs/libX11
+	)
+	|| (	<sys-libs/glibc-2.26
+		(
+			net-libs/libnsl
+			net-libs/libtirpc
+			net-libs/rpcsvc-proto
+		)
+	)
+"
+DEPEND="$RDEPEND"
+S="${WORKDIR}/${PN}"
+PATCHES=(
+	"${FILESDIR}"/${P}-configure.patch
+	"${FILESDIR}"/${P}-lvalue-gcc4.patch
+	"${FILESDIR}"/${P}-strip.patch
+	"${FILESDIR}"/${P}-misc.patch
+	"${FILESDIR}"/${P}-va_list.patch
+	"${FILESDIR}"/${P}-libtirpc.patch
+	"${FILESDIR}"/${P}-amd64-compat.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s:^#CGIFile /usr/local/share/nsat/nsat.cgi$:#CGIFile /usr/share/nsat/nsat.cgi:g" \
+		nsat.conf || die
+	sed -i -e "s:/usr/local:/usr:g" tools/xnsat || die
+	sed -i \
+		-e "s:/usr/local/share/nsat/nsat.conf:/etc/nsat/nsat.conf:g" \
+		-e "s:/usr/local/share/nsat/nsat.cgi:/usr/share/nsat/nsat.cgi:g" \
+		src/lang.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+	econf $(use_with X x)
+}
+
+src_compile() {
+	emake MIXOBJ=-lmix++
+}
+
+src_install () {
+	dobin nsat smb-ns
+	use X && dobin tools/xnsat
+
+	insinto /usr/share/nsat
+	doins nsat.cgi
+
+	insinto /etc/nsat
+	doins nsat.conf
+
+	dodoc README doc/CHANGES
+	doman doc/nsat.8
+}
-- 
2.26.2