From 3ec1af24dc972ad8c0472b01f851afa5db717932 Mon Sep 17 00:00:00 2001
From: Daniel Pielmeier <billie@gentoo.org>
Date: Thu, 5 Sep 2019 19:25:21 +0200
Subject: [PATCH] app-portage/pfl: Revison bump to pfl-3.0.1-r3.

Add support for python-3.7.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Daniel Pielmeier <billie@gentoo.org>
---
 app-portage/pfl/pfl-3.0.1-r3.ebuild | 49 +++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 app-portage/pfl/pfl-3.0.1-r3.ebuild

diff --git a/app-portage/pfl/pfl-3.0.1-r3.ebuild b/app-portage/pfl/pfl-3.0.1-r3.ebuild
new file mode 100644
index 000000000000..0683d8fadcd7
--- /dev/null
+++ b/app-portage/pfl/pfl-3.0.1-r3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+DESCRIPTION="Searchable online file/package database for Gentoo"
+HOMEPAGE="http://www.portagefilelist.de"
+SRC_URI="https://dev.gentoo.org/~billie/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+network-cron"
+
+DEPEND=""
+RDEPEND="
+	${DEPEND}
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+	net-misc/curl
+	sys-apps/portage[${PYTHON_USEDEP}]
+	network-cron? ( sys-apps/util-linux[caps] )
+"
+
+PATCHES=(
+	"${FILESDIR}/e-file-function.patch"
+)
+
+python_install_all() {
+	if use network-cron ; then
+		exeinto /etc/cron.weekly
+		doexe cron/pfl
+	fi
+
+	keepdir /var/lib/${PN}
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}/var/lib/${PN}/pfl.info" ]]; then
+		touch "${EROOT}/var/lib/${PN}/pfl.info" || die
+	fi
+	chown -R portage:portage "${EROOT}/var/lib/${PN}" || die
+	chmod 775 "${EROOT}/var/lib/${PN}" || die
+}
-- 
2.26.2