From 3c4de332cc84fafffc38193132a163628439d1b1 Mon Sep 17 00:00:00 2001
From: Austin English <wizardedit@gentoo.org>
Date: Fri, 16 Sep 2016 14:32:34 -0500
Subject: [PATCH] games-simulation/lincity: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0
---
 .../lincity/lincity-1.13.1-r1.ebuild          | 53 +++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 games-simulation/lincity/lincity-1.13.1-r1.ebuild

diff --git a/games-simulation/lincity/lincity-1.13.1-r1.ebuild b/games-simulation/lincity/lincity-1.13.1-r1.ebuild
new file mode 100644
index 000000000000..bdcd25613cce
--- /dev/null
+++ b/games-simulation/lincity/lincity-1.13.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils flag-o-matic
+
+DESCRIPTION="city/country simulation game for X and Linux SVGALib"
+HOMEPAGE="http://lincity.sourceforge.net/"
+SRC_URI="mirror://sourceforge/lincity/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="nls"
+
+# dep fix (bug #82318)
+RDEPEND="media-libs/libpng:0
+	x11-libs/libSM
+	x11-libs/libXext
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-build.patch
+)
+
+src_prepare() {
+	default
+
+	append-cflags -std=gnu89 # build with gcc5 (bug #570574)
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-gzip \
+		--with-x
+}
+
+src_compile() {
+	# build system logic is severely broken
+	emake
+	emake X_PROGS
+}
+
+src_install() {
+	default
+	dodoc Acknowledgements CHANGES README* TODO
+	make_desktop_entry xlincity Lincity
+	dobin xlincity
+}
-- 
2.26.2