From 39e359ccdec4a27c54e53271d6561bd885de7d1e Mon Sep 17 00:00:00 2001
From: =?utf8?q?Niccol=C3=B2=20Scatena?= <speedjack95@gmail.com>
Date: Sat, 9 Feb 2019 17:32:49 +0100
Subject: [PATCH] dev-libs/swayidle: Add 9999 live version
MIME-Version: 1.0
Content-Type: text/plain; charset=utf8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Niccolò Scatena <speedjack95@gmail.com>
Signed-off-by: Aaron Bauman <bman@gentoo.org>
---
 dev-libs/swayidle/swayidle-9999.ebuild | 57 ++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-libs/swayidle/swayidle-9999.ebuild

diff --git a/dev-libs/swayidle/swayidle-9999.ebuild b/dev-libs/swayidle/swayidle-9999.ebuild
new file mode 100644
index 000000000000..774758c9815e
--- /dev/null
+++ b/dev-libs/swayidle/swayidle-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Idle management daemon for Wayland"
+HOMEPAGE="https://github.com/swaywm/swayidle"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind fish-completion +man systemd zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/wayland
+	elogind? ( >=sys-auth/elogind-237[policykit] )
+	systemd? ( >=sys-apps/systemd-237[policykit] )
+"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/sway-1.0_beta1
+	!~dev-libs/sway-1.0_beta2[swayidle]
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}
-- 
2.26.2