From 387003d158393ef2f3b678f99e1b1e57bd846339 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Tue, 6 Aug 2019 22:24:38 +0200
Subject: [PATCH] net-analyzer/fragroute: Set sub-SLOT dependency on
 dev-libs/libevent

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 .../fragroute/fragroute-1.2.6-r2.ebuild       | 47 +++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 net-analyzer/fragroute/fragroute-1.2.6-r2.ebuild

diff --git a/net-analyzer/fragroute/fragroute-1.2.6-r2.ebuild b/net-analyzer/fragroute/fragroute-1.2.6-r2.ebuild
new file mode 100644
index 000000000000..1043d0fd9879
--- /dev/null
+++ b/net-analyzer/fragroute/fragroute-1.2.6-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P}-ipv6"
+
+inherit autotools
+
+DESCRIPTION="Testing of network intrusion detection systems, firewalls and TCP/IP stacks"
+HOMEPAGE="https://github.com/stsi/fragroute-ipv6"
+SRC_URI="https://fragroute-ipv6.googlecode.com/files/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	dev-libs/libevent:=
+	net-libs/libpcap
+	>=dev-libs/libdnet-1.12[ipv6]
+"
+DEPEND="
+	${RDEPEND}
+	virtual/awk
+"
+DOCS=( INSTALL README TODO )
+PATCHES=(
+	"${FILESDIR}"/${P}-pcap_open.patch
+)
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	# Remove broken and old files, autotools will regen needed files
+	rm *.m4 acconfig.h missing Makefile.in || die
+	# Add missing includes
+	sed -i -e "/#define IPUTIL_H/a#include <stdio.h>\n#include <stdint.h>" iputil.h || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-libdnet="${EPREFIX}"/usr \
+		--with-libevent="${EPREFIX}"/usr \
+		--with-libpcap="${EPREFIX}"/usr
+}
-- 
2.26.2