From 35cb76dcc66a42a8ba127b9478e6253f461f5a1c Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 2 Nov 2018 17:10:54 +0100
Subject: [PATCH] media-libs/sdl2-image: Bump to version 2.0.4

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
---
 media-libs/sdl2-image/Manifest                |  1 +
 media-libs/sdl2-image/sdl2-image-2.0.4.ebuild | 61 +++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 media-libs/sdl2-image/sdl2-image-2.0.4.ebuild

diff --git a/media-libs/sdl2-image/Manifest b/media-libs/sdl2-image/Manifest
index a9d0151408db..75143329a7b4 100644
--- a/media-libs/sdl2-image/Manifest
+++ b/media-libs/sdl2-image/Manifest
@@ -1 +1,2 @@
 DIST SDL2_image-2.0.3.tar.gz 8685512 BLAKE2B c54114f6573632561443bc57af8fe3ddbccc0bfcf027939685add7b06cb6999a5bc41119c474481047a7216ce6110a58a08571fefa6b5c80322f15f0c528ad6f SHA512 869cf3485cc850a91dc1d7f0023f0497bc7bbfd63e721365358b19d19d4da850e52667731d0e5ec80f4a11d7687aa6cfbdd5ceaec956af0e7f5567e87535977a
+DIST SDL2_image-2.0.4.tar.gz 11682695 BLAKE2B 5e2a456d770ab2b6b82d5573d9e6eed874b2b65fe3225287aef853b27f79251db4dae155721018c69f30e272d9cdd4a4f97db30ca93f63bc08e270019888edb6 SHA512 7320a5c9111908d402fbb0c12a49eb359a6db645c0c86839793ebb1a5b75eaca7c85eb96851f3a0b4a68a2f06363c8189555afd4f1048a4a41447370eddd7e6a
diff --git a/media-libs/sdl2-image/sdl2-image-2.0.4.ebuild b/media-libs/sdl2-image/sdl2-image-2.0.4.ebuild
new file mode 100644
index 000000000000..08cadf24d1c4
--- /dev/null
+++ b/media-libs/sdl2-image/sdl2-image-2.0.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib multilib-minimal
+
+MY_P="SDL2_image-${PV}"
+DESCRIPTION="Image file loading library"
+HOMEPAGE="http://www.libsdl.org/projects/SDL_image/"
+SRC_URI="http://www.libsdl.org/projects/SDL_image/release/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gif jpeg png static-libs tiff webp"
+
+RDEPEND="
+	>=media-libs/libsdl2-2.0.1-r1[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
+	jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+	tiff? ( >=media-libs/tiff-3.9.7-r1:0[${MULTILIB_USEDEP}] )
+	webp? ( >=media-libs/libwebp-0.3.0[${MULTILIB_USEDEP}] )"
+DEPEND=${RDEPEND}
+
+S="${WORKDIR}/${MY_P}"
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		--disable-sdltest
+		--enable-bmp
+		$(use_enable gif)
+		$(use_enable jpeg jpg)
+		--disable-jpg-shared
+		--enable-lbm
+		--enable-pcx
+		$(use_enable png)
+		--disable-png-shared
+		--enable-pnm
+		--enable-tga
+		$(use_enable tiff tif)
+		--disable-tif-shared
+		--enable-xcf
+		--enable-xpm
+		--enable-xv
+		$(use_enable webp)
+		--disable-webp-shared
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	multilib_is_native_abi && newbin .libs/showimage$(get_exeext) showimage2$(get_exeext)
+}
+
+multilib_src_install_all() {
+	dodoc {CHANGES,README}.txt
+	find "${ED}" -name "*.la" -delete || die
+}
-- 
2.26.2