From 34b2e63455c5b457b750f5a0167604c2211266d0 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Manuel=20R=C3=BCger?= <mrueg@gentoo.org>
Date: Thu, 10 Aug 2017 15:28:26 +0200
Subject: [PATCH] sys-cluster/kubelet: Install /var/lib/kubelet as well

Package-Manager: Portage-2.3.6, Repoman-2.3.3
---
 sys-cluster/kubelet/kubelet-1.7.3-r1.ebuild | 43 +++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 sys-cluster/kubelet/kubelet-1.7.3-r1.ebuild

diff --git a/sys-cluster/kubelet/kubelet-1.7.3-r1.ebuild b/sys-cluster/kubelet/kubelet-1.7.3-r1.ebuild
new file mode 100644
index 000000000000..8348f6d70ace
--- /dev/null
+++ b/sys-cluster/kubelet/kubelet-1.7.3-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit golang-build golang-vcs-snapshot
+
+EGO_PN="k8s.io/kubernetes"
+ARCHIVE_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Kubernetes Node Agent"
+HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
+SRC_URI="${ARCHIVE_URI}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="hardened"
+
+DEPEND="dev-go/go-bindata"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d" src/${EGO_PN}/hack/lib/golang.sh || die
+	sed -i -e "/export PATH/d" src/${EGO_PN}/hack/generate-bindata.sh || die
+}
+
+src_compile() {
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')"
+	LDFLAGS="" GOPATH="${WORKDIR}/${P}" emake -j1 -C src/${EGO_PN} WHAT=cmd/${PN}
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin _output/bin/${PN}
+	popd || die
+	keepdir /etc/kubernetes/manifests /var/log/kubelet /var/lib/kubelet
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+}
-- 
2.26.2