From 33f31b7b8b94f1b2d42aada4257621e412b08254 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Manuel=20R=C3=BCger?= <mrueg@gentoo.org>
Date: Wed, 9 Nov 2016 17:58:33 +0100
Subject: [PATCH] app-emulation/containerd: Apply -fno-PIC

Thanks to K3A

Gentoo-Bug: 591872

Package-Manager: portage-2.3.0
---
 .../containerd/containerd-0.2.4-r1.ebuild     | 44 +++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 app-emulation/containerd/containerd-0.2.4-r1.ebuild

diff --git a/app-emulation/containerd/containerd-0.2.4-r1.ebuild b/app-emulation/containerd/containerd-0.2.4-r1.ebuild
new file mode 100644
index 000000000000..4b81e8a432ac
--- /dev/null
+++ b/app-emulation/containerd/containerd-0.2.4-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+EGO_PN="github.com/docker/${PN}"
+
+inherit toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	MY_PV="${PV/_/-}"
+	EGIT_COMMIT="v${MY_PV}"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="A daemon to control runC"
+HOMEPAGE="https://containerd.tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+seccomp"
+
+DEPEND=""
+RDEPEND=">=app-emulation/runc-1.0.0_rc2
+	seccomp? ( sys-libs/libseccomp )"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+src_compile() {
+	local options=( $(usex seccomp "seccomp") ) myldflags
+	export GOPATH="${WORKDIR}/${P}" # ${PWD}/vendor
+	if gcc-specs-pie; then
+		myldflags="-extldflags -fno-PIC"
+	fi
+	LDFLAGS=${myldflags} emake GIT_COMMIT="$EGIT_COMMIT" BUILDTAGS="${options[@]}"
+}
+
+src_install() {
+	dobin bin/containerd* bin/ctr
+}
-- 
2.26.2