From 2d5741326852b417fdd124fe3940cc3cde20955d Mon Sep 17 00:00:00 2001
From: =?utf8?q?G=C3=B6kt=C3=BCrk=20Y=C3=BCksek?= <gokturk@gentoo.org>
Date: Mon, 10 Feb 2020 15:05:35 -0500
Subject: [PATCH] app-crypt/yubikey-manager: bump to 3.1.1
MIME-Version: 1.0
Content-Type: text/plain; charset=utf8
Content-Transfer-Encoding: 8bit

Bug: https://bugs.gentoo.org/708276
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>
---
 app-crypt/yubikey-manager/Manifest            |  1 +
 .../yubikey-manager-3.1.1.ebuild              | 63 +++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 app-crypt/yubikey-manager/yubikey-manager-3.1.1.ebuild

diff --git a/app-crypt/yubikey-manager/Manifest b/app-crypt/yubikey-manager/Manifest
index 826dee80d020..23ffb01a757a 100644
--- a/app-crypt/yubikey-manager/Manifest
+++ b/app-crypt/yubikey-manager/Manifest
@@ -1 +1,2 @@
 DIST yubikey-manager-3.1.0.tar.gz 115010 BLAKE2B 1b27b9af7f3adac87a1bca58929bffef2ae397b359f70580a07193d2bd2f8cd4d2d867053f6494f1e262668443388d79dfe3775f2c3d0a5528840df8826cdf91 SHA512 518eedb52cfcf725c13114c433f848b97f711e94fa9c71685916fb8cb20e5bfc431f648b0ec710ef9ebed2bc8ddd8722ca1c9865d7a1b29537b719e167ed5f60
+DIST yubikey-manager-3.1.1.tar.gz 116632 BLAKE2B 252c419280143fa6f44daf3de8ec27bbdc3218e4552e39799e1daca5b46939c4042ae1d43abeab110fe1abaf2e87d94c270442ee6fce05e26927add5b34e9f66 SHA512 8229d5442ddf89fe90abb0153aa005cb0d149a84634b994dc283f7cbac2f72d4b913c238c277c6aa07f431aed8905008aeb11e594e730be71c9ca88150a6ef68
diff --git a/app-crypt/yubikey-manager/yubikey-manager-3.1.1.ebuild b/app-crypt/yubikey-manager/yubikey-manager-3.1.1.ebuild
new file mode 100644
index 000000000000..c510503999b1
--- /dev/null
+++ b/app-crypt/yubikey-manager/yubikey-manager-3.1.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+inherit readme.gentoo-r1 distutils-r1
+
+DESCRIPTION="Python library and command line tool for configuring a YubiKey"
+HOMEPAGE="https://developers.yubico.com/yubikey-manager/"
+# Per https://github.com/Yubico/yubikey-manager/issues/217, Yubico is
+# the official source for tarballs, not Github
+SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
+	>=dev-python/fido2-0.7.0[${PYTHON_USEDEP}]
+	<dev-python/fido2-0.8.0[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/pyscard[${PYTHON_USEDEP}]
+	dev-python/pyusb[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=sys-auth/ykpers-1.19.0
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' 'python2_7')
+	)
+"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOC_CONTENTS
+
+	distutils-r1_python_install_all
+
+	DOC_CONTENTS="
+		The 'openpgp' command may require the package 'app-crypt/ccid'
+		to be installed on the system. Furthermore, make sure that pcscd
+		daemon is running and has correct access permissions to USB
+		devices.
+	"
+	readme.gentoo_create_doc
+
+	doman "${S}"/man/ykman.1
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
-- 
2.26.2