From 2bf8c71b6b0de9617e55526a2dddd9b4ed7fb76f Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 1 Jul 2017 09:30:13 +0200
Subject: [PATCH] app-office/orage: Bump to EAPI=6

---
 app-office/orage/orage-4.12.1-r1.ebuild | 67 +++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 app-office/orage/orage-4.12.1-r1.ebuild

diff --git a/app-office/orage/orage-4.12.1-r1.ebuild b/app-office/orage/orage-4.12.1-r1.ebuild
new file mode 100644
index 000000000000..85e10a53d986
--- /dev/null
+++ b/app-office/orage/orage-4.12.1-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils
+
+DESCRIPTION="A time managing application (and panel plug-in) for the Xfce desktop environment"
+HOMEPAGE="https://git.xfce.org/apps/orage/"
+SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="berkdb dbus libnotify +xfce_plugins_clock"
+
+RDEPEND=">=dev-libs/libical-0.48:=
+	dev-libs/popt:=
+	>=x11-libs/gtk+-2.10:2=
+	berkdb? ( >=sys-libs/db-4:= )
+	dbus? ( >=dev-libs/dbus-glib-0.100:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	xfce_plugins_clock? ( >=xfce-base/xfce4-panel-4.10:= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	>=sys-devel/libtool-2.2.6
+	virtual/pkgconfig"
+
+pkg_setup() {
+	# PM doesn't let directory to be replaced by a symlink, see src_install()
+	rm -rf "${EROOT}"/usr/share/${PN}/doc || die
+}
+
+src_configure() {
+	local myconf=(
+		--libexecdir="${EPREFIX}/usr/$(get_libdir)"
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		$(use_enable xfce_plugins_clock libxfce4panel)
+		$(use_enable dbus)
+		$(use_enable libnotify)
+		$(use_with berkdb bdb4)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install \
+		docdir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		imagesdir="${EPREFIX}"/usr/share/doc/${PF}/html/images
+
+	# Create compability symlink for retarded path hardcoding in src/{mainbox,parameters}.c
+	dosym /usr/share/doc/${PF}/html /usr/share/${PN}/doc/C
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
-- 
2.26.2