From 221fc267f3275a8868cec6f3227f4c66b5d33dde Mon Sep 17 00:00:00 2001
From: Matthias Maier <tamiko@gentoo.org>
Date: Sat, 4 Mar 2017 15:13:24 -0600
Subject: [PATCH] app-emulation/libvirt-glib: ebuild maintenance,

 - bump to EAPI=6
 - drop python, bug #601384

Package-Manager: Portage-2.3.3, Repoman-2.3.2
---
 .../libvirt-glib/libvirt-glib-1.0.0-r1.ebuild | 45 +++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 app-emulation/libvirt-glib/libvirt-glib-1.0.0-r1.ebuild

diff --git a/app-emulation/libvirt-glib/libvirt-glib-1.0.0-r1.ebuild b/app-emulation/libvirt-glib/libvirt-glib-1.0.0-r1.ebuild
new file mode 100644
index 000000000000..4008aaaaecb8
--- /dev/null
+++ b/app-emulation/libvirt-glib/libvirt-glib-1.0.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 vala
+
+DESCRIPTION="GLib and GObject mappings for libvirt"
+HOMEPAGE="http://libvirt.org/git/?p=libvirt-glib.git"
+SRC_URI="ftp://libvirt.org/libvirt/glib/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection nls +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# https://bugzilla.redhat.com/show_bug.cgi?id=1093633
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	>=app-emulation/libvirt-1.2.6:=
+	>=dev-libs/glib-2.38.0:2
+	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.0
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-test-coverage \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable vala)
+}
-- 
2.26.2