From 1ef670ac35412791e58e250a6f4e77fbdd80f1e9 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Manuel=20R=C3=BCger?= <mrueg@gentoo.org>
Date: Thu, 25 Jan 2018 19:49:09 +0100
Subject: [PATCH] app-emulation/cadvisor: Fix build and issues with init file

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 .../cadvisor/cadvisor-0.28.3-r1.ebuild        | 43 +++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 app-emulation/cadvisor/cadvisor-0.28.3-r1.ebuild

diff --git a/app-emulation/cadvisor/cadvisor-0.28.3-r1.ebuild b/app-emulation/cadvisor/cadvisor-0.28.3-r1.ebuild
new file mode 100644
index 000000000000..a9f0af88b2da
--- /dev/null
+++ b/app-emulation/cadvisor/cadvisor-0.28.3-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/google/cadvisor"
+
+inherit user golang-build golang-vcs-snapshot
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+COMMIT="1e567c2"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Analyzes resource usage and performance characteristics of running containers"
+HOMEPAGE="https://github.com/google/cadvisor"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /dev/null ${PN}
+}
+
+src_prepare() {
+	sed -i -e "/go get/d" src/${EGO_PN}/build/assets.sh || die
+	sed -i -e "s/git describe.*/echo ${PV} )/"\
+		-e "s/git rev-parse --short HEAD.*/echo ${COMMIT} )/"\
+		src/${EGO_PN}/build/build.sh || die
+	default
+}
+
+src_compile() {
+	pushd "src/${EGO_PN}"
+	GO_FLAGS="-v -work -x" VERBOSE="true" GOPATH="${S}:$(get_golibdir_gopath)" emake build
+	popd || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	dobin src/${EGO_PN}/${PN}
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}
-- 
2.26.2