From 1563003afc5abf3ff5fb84fa84a6a0c8024ec223 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sat, 30 Jan 2016 11:45:25 +0100
Subject: [PATCH] app-text/apvlv: Disable optional webkit support to not rely
 on obsolete versions (with security issues (#572980)

Package-Manager: portage-2.2.27
---
 app-text/apvlv/apvlv-0.1.5-r1.ebuild | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 app-text/apvlv/apvlv-0.1.5-r1.ebuild

diff --git a/app-text/apvlv/apvlv-0.1.5-r1.ebuild b/app-text/apvlv/apvlv-0.1.5-r1.ebuild
new file mode 100644
index 000000000000..e91b58b6724c
--- /dev/null
+++ b/app-text/apvlv/apvlv-0.1.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils cmake-utils gnome2-utils
+
+DESCRIPTION="Alf's PDF Viewer Like Vim"
+HOMEPAGE="https://naihe2010.github.com/apvlv/"
+SRC_URI="https://github.com/naihe2010/apvlv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug djvu"
+
+RDEPEND="
+	>=app-text/poppler-0.18:=[cairo,xpdf-headers(+)]
+	dev-libs/glib:2
+	x11-libs/gtk+:3
+	djvu? ( app-text/djvu:= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# preserve cflags
+	epatch "${FILESDIR}/${PN}-0.1.5-cflags.patch"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONFDIR=/etc/${PN}
+		-DDOCDIR=/usr/share/${PN}
+		-DMANDIR=/usr/share/man
+		-DAPVLV_WITH_HTML=OFF
+		-DAPVLV_WITH_UMD=OFF
+		-DAPVLV_WITH_TXT=ON
+		$(cmake-utils_use djvu APVLV_WITH_DJVU)
+		$(cmake-utils_use debug APVLV_ENABLE_DEBUG)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc AUTHORS NEWS README THANKS TODO
+	newicon -s 32 icons/pdf.png ${PN}.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
2.26.2