From 0d990ea59a7d94ce35756f7b6a0d0ed465ceb296 Mon Sep 17 00:00:00 2001
From: Paolo Pedroni <paolo.pedroni@iol.it>
Date: Tue, 24 Nov 2015 12:47:01 +0100
Subject: [PATCH] x11-misc/pcmanfm-qt: Version bump to 0.10.0

Thanks to Alpha Bravo <aos@ungwana.de> in bug #565952
Fixes bug #565952
---
 x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild | 54 ++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild

diff --git a/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild
new file mode 100644
index 000000000000..47cb5417e51a
--- /dev/null
+++ b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils multilib readme.gentoo
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Fast lightweight tabbed filemanager (Qt port)"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+CDEPEND=">=dev-libs/glib-2.18:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	>=lxde-base/menu-cache-0.4.1
+	>=x11-libs/libfm-1.2.0
+	x11-libs/libxcb:=
+"
+RDEPEND="${CDEPEND}
+	x11-misc/xdg-utils
+	virtual/eject
+	virtual/freedesktop-icon-theme"
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# fix multilib
+	sed -i -e "/LIBRARY\ DESTINATION/s:lib:$(get_libdir):" \
+		libfm-qt/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_install() {
+	cmake-utils_src_install
+	DOC_CONTENTS="Be sure to set an icon theme in Edit > Preferences > User Interface"
+	readme.gentoo_src_install
+}
-- 
2.26.2