From 0949f29f406e8219ced96371db7549723eb88132 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Mon, 30 Dec 2019 13:02:45 +0100
Subject: [PATCH] dev-libs/libnl: Add live ebuild for SLOT=1.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 dev-libs/libnl/libnl-1.1.9999.ebuild | 57 ++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-libs/libnl/libnl-1.1.9999.ebuild

diff --git a/dev-libs/libnl/libnl-1.1.9999.ebuild b/dev-libs/libnl/libnl-1.1.9999.ebuild
new file mode 100644
index 000000000000..e9ef685bf116
--- /dev/null
+++ b/dev-libs/libnl/libnl-1.1.9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 multilib toolchain-funcs
+
+DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
+EGIT_REPO_URI="https://github.com/tgraf/libnl-1.1-stable"
+LICENSE="LGPL-2.1"
+SLOT="1.1"
+KEYWORDS=""
+IUSE="doc static-libs"
+
+DEPEND="doc? ( app-doc/doxygen )"
+DOCS=( ChangeLog )
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-vlan-header.patch
+	"${FILESDIR}"/${PN}-1.1-flags.patch
+	"${FILESDIR}"/${PN}-1.1.3-offsetof.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/@echo/d' \
+		Makefile.rules {lib,src,tests}/Makefile || die
+	sed -i \
+		-e 's|-g ||g' \
+		Makefile.opts.in || die
+
+	if ! use static-libs; then
+		sed -i lib/Makefile -e '/OUT_AR/d' || die
+	fi
+
+	rm -f lib/libnl.a
+}
+
+src_compile() {
+	emake AR=$(tc-getAR)
+
+	if use doc ; then
+		cd "${S}/doc"
+		emake gendoc
+	fi
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		cd "${S}/doc"
+		docinto html
+		dodoc -r html/*
+	fi
+}
-- 
2.26.2