From: Patrice Clement <monsieurp@gentoo.org>
Date: Tue, 17 Jan 2017 22:51:58 +0000 (+0100)
Subject: app-misc/lsx: EAPI 6 bump.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=f7999690404f400eec1a2da59586c4d0a3b61f9a;p=gentoo.git

app-misc/lsx: EAPI 6 bump.

Package-Manager: portage-2.3.0
---

diff --git a/app-misc/lsx/lsx-0.1-r1.ebuild b/app-misc/lsx/lsx-0.1-r1.ebuild
new file mode 100644
index 000000000000..aea95629b8b9
--- /dev/null
+++ b/app-misc/lsx/lsx-0.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="list executables"
+HOMEPAGE="http://tools.suckless.org/lsx"
+SRC_URI="http://suckless.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( README )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/.*strip.*//" \
+		Makefile || die "sed failed"
+
+	sed -i \
+		-e "s/CFLAGS = -Os/CFLAGS +=/" \
+		-e "s/LDFLAGS =/LDFLAGS +=/" \
+		config.mk || die "sed failed"
+}
+
+src_compile() {
+	emake CC=$(tc-getCC)
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+
+	# collision with net-dialup/lrzsz
+	mv "${D}/usr/bin/${PN}" "${D}/usr/bin/${PN}-suckless" || die
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	elog "Run ${PN} with ${PN}-suckless"
+}