From: Tomas Mozes <hydrapolic@gmail.com>
Date: Mon, 25 Mar 2019 12:54:24 +0000 (+0100)
Subject: dev-php/pecl-mongodb: add PHP 7.3 support
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=f5bf85269fcd3acce84f43a86b9d0d35570b8ebe;p=gentoo.git

dev-php/pecl-mongodb: add PHP 7.3 support

Closes: https://bugs.gentoo.org/681132
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>
---

diff --git a/dev-php/pecl-mongodb/pecl-mongodb-1.5.3-r1.ebuild b/dev-php/pecl-mongodb/pecl-mongodb-1.5.3-r1.ebuild
new file mode 100644
index 000000000000..62a5bf128339
--- /dev/null
+++ b/dev-php/pecl-mongodb/pecl-mongodb-1.5.3-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PHP_EXT_NAME="mongodb"
+USE_PHP="php5-6 php7-1 php7-2 php7-3"
+
+inherit php-ext-pecl-r3
+
+DESCRIPTION="MongoDB database driver for PHP"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl sasl"
+
+COMMON_DEPEND="
+	php_targets_php5-6? ( dev-lang/php:5.6[json,ssl,zlib] )
+	php_targets_php7-1? ( dev-lang/php:7.1[json,ssl,zlib] )
+	php_targets_php7-2? ( dev-lang/php:7.2[json,ssl,zlib] )
+	php_targets_php7-3? ( dev-lang/php:7.3[json,ssl,zlib] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/libbson-1.13.0
+	>=dev-libs/mongo-c-driver-1.13.0[sasl?,ssl]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sasl? ( dev-libs/cyrus-sasl )"
+RDEPEND="${DEPEND}"
+BDEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	local PHP_EXT_ECONF_ARGS=(
+		--enable-mongodb
+		--with-libbson
+		--with-libmongoc
+		--with-mongodb-sasl=$(usex sasl)
+	)
+	php-ext-source-r3_src_configure
+}