From: Patrice Clement <monsieurp@gentoo.org>
Date: Mon, 17 Apr 2017 22:14:31 +0000 (+0200)
Subject: app-admin/lsat: EAPI 6 bump.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=eb4e13336c7fa0966d47492fb071c86f71912167;p=gentoo.git

app-admin/lsat: EAPI 6 bump.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---

diff --git a/app-admin/lsat/lsat-0.9.7.1-r2.ebuild b/app-admin/lsat/lsat-0.9.7.1-r2.ebuild
new file mode 100644
index 000000000000..ca91252d82d5
--- /dev/null
+++ b/app-admin/lsat/lsat-0.9.7.1-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="The Linux Security Auditing Tool"
+HOMEPAGE="http://usat.sourceforge.net/"
+SRC_URI="http://usat.sourceforge.net/code/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="minimal"
+
+DEPEND="dev-lang/perl" # pod2man
+RDEPEND="
+	${DEPEND}
+	!minimal? (
+		app-portage/portage-utils
+		net-analyzer/nmap
+		sys-apps/iproute2
+		sys-apps/which
+		sys-process/lsof
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${P}-gentoo.patch"
+	"${FILESDIR}/${P}-segfault-fix.patch"
+)
+
+HTML_DOCS=( modules.html changelog/changelog.html )
+
+src_prepare() {
+	default
+
+	# patch for segmentation fault see bug #184488
+	sed -i Makefile.in \
+		-e '/^LDFLAGS=/d' \
+		-e '/^CFLAGS=/d' \
+		|| die "sed Makefile.in"
+}
+
+src_compile() {
+	tc-export CC
+	emake CFLAGS="${CFLAGS}" all manpage
+}
+
+src_install() {
+	emake DESTDIR="${D}" install installman
+	dodoc README* *.txt
+	einstalldocs
+}