From: lramage94 <ramage.lucas@openmailbox.org>
Date: Sat, 14 Apr 2018 19:28:15 +0000 (-0400)
Subject: net-misc/zerotier: make proper use of variables.
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=e7c169c0eb1ca29f5c362c55bfd25e2a0a47c9f9;p=gentoo.git

net-misc/zerotier: make proper use of variables.

Package-Manager: Portage-2.3.24, Repoman-2.3.6
Closes: https://bugs.gentoo.org/647402
Closes: https://github.com/gentoo/gentoo/pull/8004
---

diff --git a/net-misc/zerotier/zerotier-1.2.4-r1.ebuild b/net-misc/zerotier/zerotier-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..bd328bd24296
--- /dev/null
+++ b/net-misc/zerotier/zerotier-1.2.4-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic toolchain-funcs systemd
+
+HOMEPAGE="https://www.zerotier.com/"
+DESCRIPTION="A software-based managed Ethernet switch for planet Earth"
+SRC_URI="https://github.com/zerotier/ZeroTierOne/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+S="${WORKDIR}/ZeroTierOne-${PV}"
+
+RDEPEND="
+	net-libs/miniupnpc
+	net-libs/libnatpmp
+	dev-libs/json-glib
+	net-libs/http-parser"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/gcc-4.9.3"
+
+QA_PRESTRIPPED="/usr/sbin/zerotier-one"
+
+DOCS=( README.md AUTHORS.md )
+
+src_compile() {
+	append-ldflags -Wl,-z,noexecstack
+	emake CXX="$(tc-getCXX)" one
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/${PN}.init" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	doman "${S}/doc/zerotier-"{cli.1,idtool.1,one.8}
+}