From: Johannes Huber <johu@gentoo.org>
Date: Tue, 19 Apr 2016 13:03:39 +0000 (+0200)
Subject: app-text/kchmviewer: Fix desktop file
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=d46205cf6f5dc66a61fb39f4ca63acdc7b8765c3;p=gentoo.git

app-text/kchmviewer: Fix desktop file

Gentoo-bug: 579430

Package-Manager: portage-2.2.28
---

diff --git a/app-text/kchmviewer/kchmviewer-7.5-r1.ebuild b/app-text/kchmviewer/kchmviewer-7.5-r1.ebuild
new file mode 100644
index 000000000000..2b68130c2263
--- /dev/null
+++ b/app-text/kchmviewer/kchmviewer-7.5-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit fdo-mime qmake-utils
+
+DESCRIPTION="Feature rich chm file viewer, based on Qt"
+HOMEPAGE="http://www.kchmviewer.net/"
+SRC_URI="mirror://sourceforge/kchmviewer/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="qt5"
+
+RDEPEND="
+	dev-libs/chmlib
+	dev-libs/libzip
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwebkit:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	!qt5? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtwebkit:4
+	)
+
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# fix parallel build wrt bug #527192
+	echo "src.depends = lib" >> ${PN}.pro || die
+
+	# bug #579430
+	sed -i \
+		-e "s:zip:zip;:g" \
+		packages/kchmviewer.desktop || die "Failed to fix desktop file"
+
+	eapply_user
+}
+
+src_configure() {
+	if use qt5; then
+		eqmake5
+	else
+		eqmake4
+	fi
+}
+
+src_install() {
+	dodoc ChangeLog DBUS-bindings FAQ README
+	doicon packages/kchmviewer.png
+
+	dobin bin/kchmviewer
+	domenu packages/kchmviewer.desktop
+
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}