From: Pacho Ramos <pacho@gentoo.org>
Date: Sun, 24 Jun 2018 11:52:04 +0000 (+0200)
Subject: dev-python/gcs-oauth2-boto-plugin: Add missing depend and python3.6 support
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=b8f7bc8acb8ae3156b210ab7f305c986746c2fac;p=gentoo.git

dev-python/gcs-oauth2-boto-plugin: Add missing depend and python3.6 support

Package-Manager: Portage-2.3.40, Repoman-2.3.9
---

diff --git a/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.1-r1.ebuild b/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.1-r1.ebuild
new file mode 100644
index 000000000000..38df5638f09d
--- /dev/null
+++ b/dev-python/gcs-oauth2-boto-plugin/gcs-oauth2-boto-plugin-2.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="OAuth 2.0 plugin for Google Cloud Storage credentials in the Boto library"
+HOMEPAGE="https://pypi.org/project/gcs-oauth2-boto-plugin/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.13-use-friendy-version-checks.patch"
+)
+
+# Keep versions in sync with setup.py.
+DEPEND="${PYTHON_DEPS}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/boto-2.29.1[${PYTHON_USEDEP}]
+	dev-python/google-reauth-python[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.8[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.2[${PYTHON_USEDEP}]
+	!=dev-python/oauth2client-2.0*
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.01[${PYTHON_USEDEP}]
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -i \
+		-e '/SocksiPy-branch/d' \
+		setup.py || die
+	# Make sure the unittests aren't installed.
+	mv gcs_oauth2_boto_plugin/test_oauth2_client.py ./ || die
+}
+
+python_test() {
+	${EPYTHON} "${S}"/test_oauth2_client.py || die
+}