From: Marty E. Plummer <hanetzer@startmail.com>
Date: Fri, 27 Jul 2018 23:47:40 +0000 (-0500)
Subject: x11-misc/xkeyboard-config: add live ebuild
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=a96cc242556d0bf71ad5c96cfdcd2c54c05ec129;p=gentoo.git

x11-misc/xkeyboard-config: add live ebuild

Package-Manager: Portage-2.3.41, Repoman-2.3.9
---

diff --git a/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild b/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild
new file mode 100644
index 000000000000..0f57cc43593e
--- /dev/null
+++ b/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="X keyboard configuration database"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/XKeyboardConfig"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/xkeyboard-config.git"
+	inherit autotools git-r3
+	# x11-misc/util-macros only required on live ebuilds
+	LIVE_DEPEND=">=x11-misc/util-macros-1.18"
+else
+	SRC_URI="mirror://xorg/data/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	!<x11-apps/xkbcomp-1.2.3
+	!<x11-libs/libX11-1.4.3
+"
+DEPEND="
+	${LIVE_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		--disable-selective-werror
+		--with-xkb-base="${EPREFIX}/usr/share/X11/xkb"
+		--enable-compat-rules
+		# do not check for runtime deps
+		--disable-runtime-deps
+		--with-xkb-rules-symlink=xorg
+	)
+
+	econf "${econfargs[@]}"
+}