From: Andreas Hüttel <dilfridge@gentoo.org>
Date: Thu, 28 Jul 2011 20:54:43 +0000 (+0000)
Subject: Split kdepim translations out again
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=a7125f46eea408e4f660f9719da499910dffa5a2;p=gentoo.git

Split kdepim translations out again

Package-Manager: portage-2.1.10.7/cvs/Linux x86_64
---

diff --git a/kde-base/kde-l10n/ChangeLog b/kde-base/kde-l10n/ChangeLog
index 74040b30e790..c2c60ae1e074 100644
--- a/kde-base/kde-l10n/ChangeLog
+++ b/kde-base/kde-l10n/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.99 2011/07/27 14:04:26 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.100 2011/07/28 20:54:43 dilfridge Exp $
+
+*kde-l10n-4.7.0-r1 (28 Jul 2011)
+
+  28 Jul 2011; Andreas K. Huettel <dilfridge@gentoo.org>
+  +kde-l10n-4.7.0-r1.ebuild:
+  Split kdepim translations out again
 
 *kde-l10n-4.7.0 (27 Jul 2011)
 
diff --git a/kde-base/kde-l10n/kde-l10n-4.7.0-r1.ebuild b/kde-base/kde-l10n/kde-l10n-4.7.0-r1.ebuild
new file mode 100644
index 000000000000..24028cc4a480
--- /dev/null
+++ b/kde-base/kde-l10n/kde-l10n-4.7.0-r1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.7.0-r1.ebuild,v 1.1 2011/07/28 20:54:43 dilfridge Exp $
+
+EAPI="3"
+
+inherit kde4-base
+
+DESCRIPTION="KDE internationalization package"
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2"
+
+DEPEND="
+	sys-devel/gettext
+"
+RDEPEND="!<kde-misc/konq-plugins-4.6"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+handbook"
+
+# /usr/portage/distfiles $ ls -1 kde-l10n-*-${PV}.* |sed -e 's:-${PV}.tar.bz2::' -e 's:kde-l10n-::' |tr '\n' ' '
+MY_LANGS="ar bg bs ca ca@valencia cs da de el en_GB es et eu fi fr ga gl he hr
+hu ia id is it ja kk km kn ko lt lv nb nds nl nn pa pl pt pt_BR ro ru sk sl sr
+sv th tr ug uk wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.bz2 )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	# For EAPI >= 3, or if not using .tar.xz archives:
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="${PN}-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+			fi
+		done
+	fi
+}
+
+src_prepare() {
+	# Upstream added kdepim-runtime translations by mistake and does not want to
+	# make a new tarball, bug 366353
+
+	find "${S}" -name CMakeLists.txt -type f \
+		-exec sed -i -e 's:add_subdirectory(kdepim-runtime):# no kdepim-runtime:g' {} +
+	find "${S}" -name CMakeLists.txt -type f \
+		-exec sed -i -e 's:add_subdirectory(kdepim):# no kdepim:g' {} +
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook docs)
+	)
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_test() {
+	[[ -n ${A} ]] && kde4-base_src_test
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}