From: Jeroen Roovers <jer@gentoo.org>
Date: Mon, 13 May 2019 09:03:12 +0000 (+0200)
Subject: x11-misc/lineak-defaultplugin: Set --with-lineak-plugindir
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=8d0d28ce51558e215aec16bdb58794ebc9bebb4c;p=gentoo.git

x11-misc/lineak-defaultplugin: Set --with-lineak-plugindir

Fixes: https://bugs.gentoo.org/677480
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---

diff --git a/x11-misc/lineak-defaultplugin/lineak-defaultplugin-0.9.0-r2.ebuild b/x11-misc/lineak-defaultplugin/lineak-defaultplugin-0.9.0-r2.ebuild
new file mode 100644
index 000000000000..16aac45e5d34
--- /dev/null
+++ b/x11-misc/lineak-defaultplugin/lineak-defaultplugin-0.9.0-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib
+
+MY_P=${P/.0/}
+
+DESCRIPTION="Mute/unmute and other macros for LINEAK"
+HOMEPAGE="http://lineak.sourceforge.net"
+SRC_URI="mirror://sourceforge/lineak/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug"
+
+RDEPEND="
+	=x11-misc/lineakd-${PV}*
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+S=${WORKDIR}/${MY_P}
+DOCS=(
+	AUTHORS README
+)
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc43.patch
+	"${FILESDIR}"/${P}-gcc47.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's:$(DESTDIR)${DESTDIR}:$(DESTDIR):' default_plugin/Makefile.in || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		--with-lineak-plugindir="${EROOT}/usr/$(get_libdir)/lineakd" \
+		USER_LDFLAGS="${LDFLAGS}"
+}