From: David Seifert <soap@gentoo.org>
Date: Mon, 6 Feb 2017 20:47:59 +0000 (+0100)
Subject: sci-biology/qrna: Modernise to EAPI 6
X-Git-Url: http://git.tremily.us/gitweb.cgi?a=commitdiff_plain;h=7fe9f899f4328587aaf260203ac63a0c282bb09c;p=gentoo.git

sci-biology/qrna: Modernise to EAPI 6

* Remove ppc from KEYWORDS

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/3856
---

diff --git a/sci-biology/qrna/qrna-2.0.3c-r1.ebuild b/sci-biology/qrna/qrna-2.0.3c-r2.ebuild
similarity index 64%
rename from sci-biology/qrna/qrna-2.0.3c-r1.ebuild
rename to sci-biology/qrna/qrna-2.0.3c-r2.ebuild
index f8834630acee..f88836ed70ee 100644
--- a/sci-biology/qrna/qrna-2.0.3c-r1.ebuild
+++ b/sci-biology/qrna/qrna-2.0.3c-r2.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=4
+EAPI=6
 
-inherit eutils toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="Prototype ncRNA genefinder"
 HOMEPAGE="http://selab.janelia.org/software.html"
@@ -12,7 +12,7 @@ SRC_URI="mirror://gentoo/${P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~ppc x86"
+KEYWORDS="~amd64 ~x86"
 IUSE=""
 
 RDEPEND="
@@ -20,38 +20,40 @@ RDEPEND="
 	sci-biology/hmmer"
 DEPEND="${RDEPEND}"
 
+PATCHES=(
+	"${FILESDIR}"/${P}-glibc-2.10.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
 src_prepare() {
-	epatch \
-		"${FILESDIR}"/${P}-glibc-2.10.patch \
-		"${FILESDIR}"/${P}-ldflags.patch
+	default
 	sed \
 		-e "s:^CC.*:CC = $(tc-getCC):" \
 		-e "/^AR/s:ar:$(tc-getAR):g" \
 		-e "/^RANLIB/s:ranlib:$(tc-getRANLIB):g" \
 		-e "/CFLAGS/s:=.*$:= ${CFLAGS}:" \
 		-i {src,squid,squid02}/Makefile || die
-	rm -v squid*/*.a
+	rm -v squid*/*.a || die
 }
 
 src_compile() {
-	local dir
-	for dir in squid squid02 src; do
-		emake -C ${dir}
+	local d
+	for d in squid squid02 src; do
+		emake -C ${d}
 	done
 }
 
-src_install () {
+src_install() {
 	dobin src/{cfgbuild,eqrna,eqrna_sample,rnamat_main} scripts/*
 
 	newdoc 00README README
-	insinto /usr/share/doc/${PF}
-	doins documentation/*
+	dodoc -r documentation/.
 
 	insinto /usr/share/${PN}/data
-	doins lib/*
+	doins -r lib/.
 	insinto /usr/share/${PN}/demos
-	doins Demos/*
+	doins -r Demos/.
 
-	# Sets the path to the QRNA data files.
+	# Sets the path to the QRNA data files
 	doenvd "${FILESDIR}"/26qrna
 }